batch script variable unset in for loop has no effect

Question

Below is my script. I am trying to look into folders one level below and pick out only those folders, hence the ~-9 which extracts the last 9 chars from the path. But the set var= does not unset the variable because the output comes back with the same folder name repeated # times. Also batch doesn't allow me to do this extract trick directly on %%i, hence the need for the local variable.

How do I clear this variable so that it takes the new value in the next iteration?

@echo off
 for /d %%i in (%1\*) do (
  set var=%%i
  echo %var:~-9%
   set "var="
)

Jai · Accepted Answer · 2012-07-11 20:10:35Z

2

http://judago.webs.com/variablecatches.htm has an explanation for my problem. The magic lines were setlocal enabledelayedexpansion and calling var as echo !var:~-9!. ! vs % ...wow! cmd still amazes me.

answered Jul 11, 2012 at 20:10

Jai

3192 gold badges10 silver badges32 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

dbenham Over a year ago

+1, good job finding the source of your problem. You still have a potential problem if names contain !.

dbenham · Accepted Answer · 2012-07-11 20:28:43Z

You found the source of your problem, as well as the solution - delayed expansion.

But using FOR while delayed expansion is enabled can cause problems if any of the filenames contain the ! character. The expansion of the for variable %%i will be corrupted if the value contains ! and delayed expansion is enabled. This is not a frequent problem, but it happens.

The solution is to toggle delayed expansion on and off within the loop

@echo off
setlocal disableDelayedExpansion
for /d %%i in (%1\*) do (
  set var=%%i
  setlocal enableDelayedExpansion
  echo !var:~-9!
  endlocal
)

I'm also wondering what you mean by "I am trying to look into folders one level below and pick out only those folders, hence the ~-9 which extracts the last 9 chars from the path". I suspect your are trying to get the name of the child folder, without the leading path information. If that is so, then using the substring operation is not a good solution because the length of folder names varies.

There is a very simple method to get the name of the folder without the leading path info:

for /d %%i in (%1\*) do echo %%~nxi

Collectives™ on Stack Overflow

batch script variable unset in for loop has no effect

2 Answers 2

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related