Clojure Regex Macro

Question

I'm trying to create a macro that accepts 2 strings, 1 would be a regex pattern and the other a string to test it on. From some reading (including around here) and seeing as #"" is a reader macro I tried doing it using re-pattern but it seems to fail at runtime with:

Exception in thread "main" java.lang.ClassCastException: clojure.lang.Symbol cannot be cast to java.lang.CharSequence

My code:

(defmacro checkre [ strre strstring ] 
  (re-find (re-pattern strre) strstring))

Example call:

(defn hasthing [xp]
  (checkre "(?i)^.*blabla" xp))

Thanks!

JohnJ · Accepted Answer · 2013-01-28 19:58:13Z

4

You are close; but you don't need (and probably shouldn't use) a macro for this:

(defn checkre [ strre strstring ] 
  (re-find (re-pattern strre) strstring))
(defn hasthing [xp]
  (checkre "(?i)^.*blabla" xp))
(hasthing "stuff blabla")
;=> "stuff blabla"

Macros are best used only when needed, because they don't compose as easily as functions and are harder to reason about (because of the macro expansion phase).

The reason your macro version fails is that it is trying to bind strre and strstring at macro expansion time, when they are symbols, rather than strings. A (slightly perverted) macro version which works is:

(defmacro checkre [ strre strstring ] 
  `(re-find ~(re-pattern strre) ~strstring))
(defn hasthing [xp]
  (checkre "(?i)^.*blabla" xp))
(hasthing "stuff blabla")
;=> "stuff blabla"

answered Jan 28, 2013 at 19:58

JohnJ

4,8432 gold badges30 silver badges40 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

NielsK · Accepted Answer · 2013-01-28 20:20:06Z

1

Why would you make this a macro ? Just make it a function and it will work fine.

=> (defn checkre 
     [strre strstring] 
     (re-find (re-pattern strre) strstring))
#'user/checkre
=> (checkre "[aeiou]" "Hello")
"e"

If you want to create a function that binds the regexp, let your function return a function

=> (defn checkre 
     [strre] 
     (fn [strstring] (re-find (re-pattern strre) strstring)))
=> (def hasthing (checkre "[aeiou]"))
=> (hasthing "Hello")
"e"

edited Jan 28, 2013 at 20:20

answered Jan 28, 2013 at 19:58

NielsK

6,9561 gold badge26 silver badges46 bronze badges

Collectives™ on Stack Overflow

Clojure Regex Macro

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related