Windows batch file to create csv list of file and dates

Question

I need to create a Windows batch file that generates a .csv file with three fields for all the files in a directory (minus the batch file itself!).

Fields:

File name (this can include commas!)
Creation date
Modified date

Note that the batch file will be run from the directory, and should know to generate the .csv file for the files in the current directory, but should not list the batch file or the generated .csv file.

Powershell, vbscript, and the like are not feasible in my situation, so it has to be a Windows batch file.

EDIT:

Here are the two main approaches that I have tried.

First attempt: I've tried separating the bare file names into "temp1.tmp", the file list with the created timestamps into "temp2.tmp", and the file list with the modified timestamps into "temp3.tmp".

DIR /B /A:-D-H | FIND /V "Print Files.bat" | FIND /V "File List" | FIND /V "temp"  > "temp1.tmp"
DIR /A:-D-H /T:C | FIND /V "Print Files.bat" | FIND /V "File List" | FIND /V "temp"  > "temp2.tmp"
DIR /A:-D-H /T:W | FIND /V "Print Files.bat" | FIND /V "File List" | FIND /V "temp"  > "temp3.tmp"

MORE +5 "temp2.tmp" > "temp4.tmp"
COPY /Y "temp4.tmp" "temp2.tmp"
MORE +5 "temp3.tmp" > "temp4.tmp"
COPY /Y "temp4.tmp" "temp3.tmp"
DEL /F/Q "temp4.tmp"

But the problem with this approach is that I cannot figure out how to read lines from more than one file at a time. Here is the closest that I have found, but it is only from one file:

FOR /F "delims=" %%i IN (temp1.tmp) DO (
    ECHO."%%i" >> "File List.csv"
)

Second attempt: I've tried avoiding using temporary files, but to no avail.

FOR %%i IN (*.*) DO @ECHO "%%~ni%%~xi",%%~ti >> "File List.csv"

The problem with this second approach is that it doesn't exclude the batch file name, and it doesn't provide the file creation timestamp.

Is there a solution to make either of these work for me, or an approach that I haven't tried yet?

SO is not a "write code for me free" type of site. What have you tried so far? — Ansgar Wiechers
– Ansgar Wiechers, Commented Aug 6, 2013 at 19:10
@AnsgarWiechers & Ken White: You are both correct. I was in too much of a hurry when I wrote the question and forgot to describe my attempts at solving the problem. — Elessar
– Elessar, Commented Aug 6, 2013 at 21:02
@Endoro: AM/PM - The DIR command gives the timestamp as mm/dd/yyyy hh:mm AM (or PM) — Elessar
– Elessar, Commented Aug 6, 2013 at 21:27

Endoro · Accepted Answer · 2013-08-06 22:32:31Z

5

try this:

@ECHO OFF &SETLOCAL
(FOR /f "delims=" %%a IN ('dir /b /a-d') DO (
    FOR /f "tokens=1-3*" %%x IN ('dir /a-d /tc "%%~a"^|findstr "^[0-9]"') DO (
        ECHO "%%a",%%~ta,%%x %%y %%z
    )
))>DIR.csv
TYPE DIR.csv

edited Aug 6, 2013 at 22:32

answered Aug 6, 2013 at 21:35

Endoro

37.7k8 gold badges54 silver badges64 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Elessar Over a year ago

This also does the job, and is a bit easier to understand.

Ansgar Wiechers · Accepted Answer · 2013-08-06 21:33:58Z

2

Something like this might work:

@echo off

setlocal EnableDelayedExpansion

(
  echo "Name","Modification Time","Creation Time"
  for %%f in (*) do (
    set "name=%%~nxf"
    if not "!name!"=="%~nx0" (
      set "mtime=%%~tf"
      for /f "tokens=1-3" %%d in (
        'dir /t:c "!name!" ^| find /i "!name!"'
      ) do set "ctime=%%~d %%~e %%~f"
      echo "!name!","!mtime!","!ctime!"
    )
  )
) > output.csv

answered Aug 6, 2013 at 21:33

Ansgar Wiechers

202k27 gold badges286 silver badges363 bronze badges

3 Comments

Elessar Over a year ago

Thanks! Although the names of batch file and the csv file aren't excluded, I'm sure that I can figure that part out. I would upvote the answer, but I don't have enough reputation.

Ansgar Wiechers Over a year ago

The name of the batch file is excluded. The name of the CSV isn't, though.

Elessar Over a year ago

You are correct. I was looking at a different file on the list.

dbenham · Accepted Answer · 2014-12-25 14:49:07Z

1

Here is a command line one liner that does not include the newly create list file in the list:

(for /f "tokens=1-4*" %A in ('dir /a-d /tc^|findstr "^[0-9]"') do @if "%E" neq "FileList.csv" echo "%E",%A %B %C,%~tE)>"FileList.csv"

Here is a batch script that does not include itself or the newly created list file:

@echo off
>"FileList.csv" (
  for /f "tokens=1-4*" %%A in (
    'dir /a-d /tc^|findstr "^[0-9]"'
  ) do if "%~f0" neq "%%~fE" if "%%E" neq "FileList.csv" echo "%%E",%%A %%B %%C,%%~tE
)

answered Dec 25, 2014 at 14:49

dbenham

132k29 gold badges273 silver badges410 bronze badges

Comments

Andrew · Accepted Answer · 2014-09-17 21:29:19Z

0

A one-line PowerShell command to write directory listing to CSV

answered Sep 17, 2014 at 21:29

Andrew

1,6183 gold badges19 silver badges25 bronze badges

Comments

Sarath Subramanian · Accepted Answer · 2016-09-03 10:55:12Z

0

I had a requirement to read the number of lines in two files and output to a csv file.

@ECHO OFF
cd "D:\CSVOutputPath\"
echo Process started, please wait...
echo FILENAME,FILECOUNT> SUMMARY.csv
for /f %%C in ('Find /V /C "" ^< "D:\Trial\Salary.txt"') do set Count=%%C
echo Salary,%Count%>> SUMMARY.csv
for /f %%C in ('Find /V /C "" ^< "D:\Trial\Tax.txt"') do set Count=%%C
echo Tax,%Count%>> SUMMARY.csv

The > will overwrite the existing content of the file and the >> will append the new data to existing data

answered Sep 3, 2016 at 10:55

Sarath Subramanian

21.6k12 gold badges89 silver badges95 bronze badges

Collectives™ on Stack Overflow

Windows batch file to create csv list of file and dates

5 Answers 5

1 Comment

3 Comments

Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

5 Answers 5

1 Comment

3 Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related