Delete an item from a clojure vector using index

Question

I want to do something that looks similar to replace but performs different operation.
Using replace will create a new vector containing the corresponding value(s) of the index provided.

example

(replace [10 9 8 7 6] [0 4])     ;;=> [10 6]

My question now is that is there a way to create a new vector that will exclude the corresponding value(s) of the index provided? i.e delete the values of the index provided from the vector.

the code below is just an illustration. "some-function means something needs to be there"  
( 'some-function'   [10 9 8 7 6] [0 4])    ;;=> [9 8 7]

Are you, as some answers suggest, deleting a subrange, always given by two indexes? Or, as others assume, are you providing a sequence of any number of indexes to delete the values of? — Thumbnail
– Thumbnail, Commented Aug 8, 2015 at 11:11

RedDeckWins · Accepted Answer · 2015-08-06 12:56:21Z

1

I don't know of a native function that does what you want. If you were working with Maps you could use dissoc.

You can write your own function to do this. Here is one way (of many) below.

(defn dissoc-vec
  ([v ks]
    (let [pred (set ks)
          replace-keys (->> (range (count v))
                            (remove #(pred %))
                            vec)]
      (replace v replace-keys))))

answered Aug 6, 2015 at 12:56

RedDeckWins

2,12114 silver badges16 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Leon Grapenthin Over a year ago

Note that this takes linear time while dissoc is a nearly constant time op.

amalloy Over a year ago

This has to take linear time, because the vector data structure does not have a way to support fast indexed removal.

Thumbnail Over a year ago

Your (remove #(pred %)) is just (remove pred), as @amalloy once pointed out to me :).

user2524973 · Accepted Answer · 2015-08-06 14:12:27Z

0

check out subvec.

to achieve the exact function you want, you can do this:

(fn [coll [a b]]
  (subvec coll (inc a) b))

answered Aug 6, 2015 at 14:12

user2524973

1,1176 silver badges14 bronze badges

3 Comments

Leon Grapenthin Over a year ago

Note that a vector returned by subvec only returns a view on the input vector, hence the input vector won't be garbage collected.

amalloy Over a year ago

Also you can't productively conj elements back onto the subvector, without it internally copying the original vector anyway.

Leon Grapenthin Over a year ago

@amalloy Do you have a reference?

Leon Grapenthin · Accepted Answer · 2015-08-06 15:25:20Z

0

You probably need https://github.com/clojure/core.rrb-vector

[...]clojure.core.rrb-vector/subvec, which produces a new vector containing the appropriate subrange of the input vector (in contrast to clojure.core/subvec, which returns a view on the input vector).

answered Aug 6, 2015 at 15:25

Leon Grapenthin

9,29626 silver badges37 bronze badges

Comments

Thumbnail · Accepted Answer · 2015-08-08 11:04:54Z

0

You can do this with the sequence functions as follows:

(defn remove-indexes [indexes coll]
  (->> coll
       (map-indexed vector)
       (remove (comp (set indexes) first))
       (map second)
       vec))

(remove-indexes [0 4] [10 9 8 7 6])
;[9 8 7]

I've switched the arguments around to correspond with core remove.
Since it works on any collection, you might omit the final vec.

A transducer version is probably a bit quicker:

(defn remove-indexes [is v]
  (into [] 
        (comp (map-indexed vector)
              (remove (comp (set is) first))
              (map second))
        v))

answered Aug 8, 2015 at 11:04

Thumbnail

13.5k2 gold badges31 silver badges39 bronze badges

Collectives™ on Stack Overflow

Delete an item from a clojure vector using index

4 Answers 4

3 Comments

3 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

3 Comments

3 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related