Adding element in middle of xml using xslt

Question

Below is the actual xml:

<?xml version="1.0" encoding="utf-8"?>
<employee>
 <Name>ABC</Name>
 <Dept>CS</Dept>
 <Designation>sse</Designation>
</employee>

And i want the output as below:

<?xml version="1.0" encoding="utf-8"?>
<employee>
 <Name>ABC</Name>
  <Age>34</Age>
 <Dept>CS</Dept>
  <Domain>Insurance</Domain>
 <Designation>sse</Designation>
</employee>

Is this possible to add XML element in between using xslt? Please give me sample!

LarsH · Accepted Answer · 2013-03-17 20:28:34Z

47

Here is an XSLT 1.0 stylesheet that will do what you asked:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <!-- Identity transform -->
   <xsl:template match="@* | node()">
      <xsl:copy>
         <xsl:apply-templates select="@* | node()"/>
      </xsl:copy>
   </xsl:template>

   <xsl:template match="Name">
      <xsl:copy-of select="."/>
      <Age>34</Age>
   </xsl:template>

   <xsl:template match="Dept">
      <xsl:copy-of select="."/>
      <Domain>Insurance</Domain>
   </xsl:template>
</xsl:stylesheet>

Obviously the logic will vary depending on where you will be getting the new data from, and where it needs to go. The above stylesheet merely inserts an <Age> element after every <Name> element, and a <Domain> element after every <Dept> element.

(Limitation: if your document could have <Name> or <Dept> elements within other <Name> or <Dept> elements, only the outermost ones will have this special processing. I don't think you intend for your document to have this kind of recursive structure, so it wouldn't affect you, but it's worth mentioning just in case.)

edited Mar 17, 2013 at 20:28

answered Sep 6, 2010 at 6:45

LarsH

28.1k9 gold badges99 silver badges162 bronze badges

Sign up to request clarification or add additional context in comments.

5 Comments

Joe Over a year ago

What if you only want the element to be added once, instead of once for every Name/Dept elements?

LarsH Over a year ago

@Joe: Wow, almost 5 years later. :-) In that case you add the result element in a template that will only match once. E.g. match="/*/Name[1]".

Joe Over a year ago

Excellent, I didn't really expect an answer 5 years later, much less one so prompt! That helps a lot

GLP Over a year ago

What if I want to pass age (34) as a parameter? I don't want to hard-coded 34 in the xslt file.

LarsH Over a year ago

@GLP: It depends on where you want to pass it from. I would recommend creating a new question.

sathya · Accepted Answer · 2016-09-06 17:34:38Z

I have modified few things in the existing stylesheet ,it will allow you to choose the specific element and update in your xml.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   <!-- Identity transform -->
   <xsl:template match="@* | node()">
      <xsl:copy>
         <xsl:apply-templates select="@* | node()"/>
      </xsl:copy>
   </xsl:template>

   <xsl:template match="Name[1]">
      <xsl:copy-of select="."/>
      <Age>34</Age>
   </xsl:template>

   <xsl:template match="Dept[1]">
      <xsl:copy-of select="."/>
      <Domain>Insurance</Domain>
   </xsl:template>
</xsl:stylesheet>

XML:

<?xml version="1.0" encoding="utf-8"?>
<employee>
 <Name>ABC</Name>
 <Dept>CS</Dept>
 <Designation>sse</Designation>
 <Name>CDE</Name>
 <Dept>CSE</Dept>
 <Designation>sses</Designation>
</employee>

Collectives™ on Stack Overflow

Adding element in middle of xml using xslt

2 Answers 2

5 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

5 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related