Adding multiple arrays at once perl

Question

I have about 50 arrays filled with numbers and I have to report out a sum of all those elements for every array so the end result has 50 sums of individual arrays.

Is there any shorter way to do it rather than writing different for loop for every array?

I am a beginner with perl. Any helpful comments/suggestions would be appreciated.

This is my code so far:

for( $j = 1 ; $j <= 50 ; $j++ ) {
  for ( @arr[$j] ) {
    $sum[$j] += $_;
  }
  print $sum[$j];
}

Thank you!

How are the 50 arrays structured? Do you have an "array of arrays", or do you have 50 individual arrays? — David
– David, Commented Jul 5, 2012 at 15:57
Your looping appears to be off by one, er, by two, starting at the second element of @arr (index $j is 1) and ending at the fifty-first element (index 50). Perl's more expressive loops — for my $whatever (@whatevers) — avoid this kind of error, as does while (my ($index, $element) = each(@array)) available in 5.12 and later. — pilcrow
– pilcrow, Commented Jul 5, 2012 at 16:23

TLP · Accepted Answer · 2012-07-05 15:57:10Z

7

You can use List::Util and map, assuming you have an array of arrays:

use strict;
use warnings;
use Data::Dumper; 
use List::Util qw(sum);

my @arrays = (
    [1,2,3],
    [4,5,6],
    [7,8,9]
); 
my @sums   = map sum(@$_), @arrays;   # sum each array
print Dumper \@sums;

Output:

$VAR1 = [
          '6',       # sum of $arrays[0]
          '15',      #                1
          '24'       #                2
        ];

answered Jul 5, 2012 at 15:57

TLP

68.2k10 gold badges97 silver badges156 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

user1297069 Over a year ago

Hey I really appreciate your answer and it works perfectly fine but my output has to be displayed in a proper way. Is there anyway I can get rid of "$VAR1" in my output and put some other text before sums of every array? what I need to do is: Sum of array 1: 6 Sum of array 2: 15 Sum of array 3: 24 and so on I would really appreciate your feedback on this. Thanks a lot!

TLP Over a year ago

@user1297069 Well, I assumed you would know with your own data, but one way to do that particular print is print "Sum of array $_: $sums[$_]\n" for keys @sums

user1297069 Over a year ago

alright cool thanks again for all your help! Def made my job much easier

Sinan Ünür · Accepted Answer · 2012-07-05 15:59:55Z

4

use strict; use warnings;

use List::Util qw ( sum );

my %data = (
   cats => [ map +(rand 100), 1 .. 10 ],
   dogs => [ map +(100 - rand 100), 1 .. 20 ],
);

my %sums = map { $_ => sum(@{ $data{$_} }) } keys %data;

use YAML;
print Dump \%data, \%sums;

answered Jul 5, 2012 at 15:59

Sinan Ünür

118k15 gold badges201 silver badges347 bronze badges

Comments

raina77ow · Accepted Answer · 2012-07-05 16:41:50Z

For TIMTOWTDI!

# You cannot store arrays within arrays just with ((...), (...)) syntax, 
# as this list will be flattened.
# Instead you should store _references_ to arrays, like this:
my @array_of_arrays = ([1..3], [4..6], [8..10]); 
my @sums_of_arrays;

# ... then iterate over it, arrayref by arrayref
# (if `map` is somehow not for you) :)
for my $ref_arr (@array_of_arrays) {
   my $arr_sum;
   for my $el (@$ref_arr) {
     $arr_sum += $el;
   }
   push @sums_of_arrays, $arr_sum;
}

Take note, though, that I consider this solution inferior to those given by @TLP and @SinanÜnür. ) For construct is good when you need to do something (transform, for example) with each element of array (or array of arrays, as in this case). But here you just need something for each element - in other words, a map. )

Collectives™ on Stack Overflow

Adding multiple arrays at once perl

3 Answers 3

3 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

3 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related