Adding a node to to another in XSLT

Question

I have xml like this:

  <configurationData>
    <path name='b'>
      <path name='a'>
        <setting name='s1'>
        ![CDATA[XXXX]]
        </setting>
        <setting name='s2'>
          XXXX
        </setting>
      </path>
    </path>
  </configurationData>

where configurationData is the root node, and there can be may nested paths followed by one or more setting nodes. I want to convert the setting node to put the contents of the setting node into a child node called value

  <configurationData>
    <path name='b'>
      <path name='a'>
        <setting name='s1'>
          <value>![CDATA[XXXX]]</value>
        </setting>
        <setting name='s2'>
          <value>XXXX</value>
        </setting>
      </path>
    </path>
  </configurationData>

I must admit I find XML a mental road block and I cannot see what XSLT to use:

This is my attempt:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output encoding ="utf-8" indent="yes" method="xml" version="1.0"/>

  <xsl:template match='/setting'>
    <xsl:apply-templates select='setting' />
  </xsl:template>

  <xsl:template match='setting'>
    <value>
      <xsl:value-of select='.'/>
    </value>
  </xsl:template>
</xsl:stylesheet>

Preet Sangha · Accepted Answer · 2009-10-11 20:32:10Z

3

You are 90% of the way there. What you need is the "identity template"

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output encoding ="utf-8" indent="yes" method="xml" version="1.0"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match='setting'>
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <value>
                <xsl:value-of select='.'/>
            </value>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

The first template processes all nodes, copying them to the output. However, the 'setting' template, being more specific, gets invoked for 'setting' nodes, That template copies the node itself and its attributes, then wraps the value in a 'value' tag.

The most non-intiutive thing about XSLT is that the stylesheet is not a program which drives the process. Instead, it is the input XML document that controls, with the stylesheet providing instructions that get selected and executed according to what's in the input. This is called "push" processing. The XSL processor pushes data to your stylesheet. XSLT does have some procedural capabilities, and you can write a stylesheet in "pull" style, where the stylesheet attempts to drive the process, but this is harder and leads to hard-to-maintain stylesheets.

Edit: To enable CDATA sections replace:

<xsl:value-of select='.' />

with

![CDATA[<xsl:value-of select='.' disable-output-escaping="yes"/>]]

(though not the best solution as it always puts CDATA in)

edited Oct 11, 2009 at 20:32

Preet Sangha

65.7k20 gold badges152 silver badges227 bronze badges

answered Oct 9, 2009 at 3:42

Jim Garrison

87k20 gold badges162 silver badges197 bronze badges

Sign up to request clarification or add additional context in comments.

6 Comments

Preet Sangha Over a year ago

Fantastic jim. Only one little issue - the CDATA info is transliterated. I need the CDATA preserved as CDATA.

Preet Sangha Over a year ago

Just a thought. I suppose I could just using a CDATA always couldn't I?

Tomalak Over a year ago

@Preet Sangha: Yes, by declaring cdata-section-elements - see my answer. However, I would not care if it comes out as CDATA or not, since on the "data level" it is equivalent.

Tomalak Over a year ago

@Jim Garrison: +1. The complexity can be reduced some more in the second template by matching setting/text() specifically.

Preet Sangha Over a year ago

@jim: i need to retain this as the information needs to be hand editable as well as machine. The transliteration makes it very hard to maintain the data. But Thank you. I'll look up the cdata-section stuff. Muchos gracias.

|

Tomalak · Accepted Answer · 2009-10-09 08:49:36Z

0

My suggestion, based on Jim Garrison answer:

<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:output method="xml" encoding="utf-8" cdata-section-elements="value" />

  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="setting/text()">
    <value>
      <xsl:value-of select="." />
    </value>
  </xsl:template>

</xsl:stylesheet>

answered Oct 9, 2009 at 8:49

Tomalak

339k68 gold badges547 silver badges635 bronze badges

2 Comments

Preet Sangha Over a year ago

thank you very much. could you indicate why this may be better please?

Tomalak Over a year ago

It is a little bit less complex and more idiomatic. Other than that, there is not much difference.

Collectives™ on Stack Overflow

Adding a node to to another in XSLT

2 Answers 2

6 Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

6 Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related