Extract numeric data from string in groovy

Question

I am given a string that can include both text and numeric data:

Examples:

"100 pounds" "I think 173 lbs" "73 lbs."

I am looking for a clean way to extract only the numeric data from these strings.

Here is what I'm currently doing to strip the response:

def stripResponse(String response) {
    if(response) {
        def toRemove = ["lbs.", "lbs", "pounds.", "pounds", " "]
        def toMod = response
        for(remove in toRemove) {
            toMod = toMod?.replaceAll(remove, "")
        }
        return toMod
    }
}

tim_yates · Accepted Answer · 2013-03-22 14:53:18Z

35

You could use findAll then convert the results into Integers:

def extractInts( String input ) {
  input.findAll( /\d+/ )*.toInteger()
}

assert extractInts( "100 pounds is 23"  ) == [ 100, 23 ]
assert extractInts( "I think 173 lbs"   ) == [ 173 ]
assert extractInts( "73 lbs."           ) == [ 73 ]
assert extractInts( "No numbers here"   ) == []
assert extractInts( "23.5 only ints"    ) == [ 23, 5 ]
assert extractInts( "positive only -13" ) == [ 13 ]

If you need decimals and negative numbers, you might use a more complex regex:

def extractInts( String input ) {
  input.findAll( /-?\d+\.\d*|-?\d*\.\d+|-?\d+/ )*.toDouble()
}

assert extractInts( "100 pounds is 23"   ) == [ 100, 23 ]
assert extractInts( "I think 173 lbs"    ) == [ 173 ]
assert extractInts( "73 lbs."            ) == [ 73 ]
assert extractInts( "No numbers here"    ) == []
assert extractInts( "23.5 handles float" ) == [ 23.5 ]
assert extractInts( "and negatives -13"  ) == [ -13 ]

edited Mar 22, 2013 at 14:53

answered Mar 22, 2013 at 14:20

tim_yates

172k29 gold badges359 silver badges354 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

Joel Miller Over a year ago

Solution that I ended up implementing based on advice above, I only want to grab the first number (if there are multiples I invalidate the response). Thanks @tim_yates !

def extractNumericData(String response) {         if(response) {             def numberList = response.findAll( /[0-9]+.[0-9]*|[0-9]*.[0-9]+|[0-9]+/ )              if(numberList.size() == 1) {                 return numberList.get(0) as BigDecimal             } else {                 return -1             }         }     }

hiquetj Over a year ago

For some reason I get this: java.lang.UnsupportedOperationException: spread not yet supported in input.findAll(\d+)*.toInteger() . ---- And it says on Jenkins its resolved.

hiquetj · Accepted Answer · 2019-01-15 18:16:21Z

9

Putting this here for people that also need this.

Instead of creating new question, all I needed was one number from a string.

I did this with regex.

def extractInt( String input ) {
  return input.replaceAll("[^0-9]", "")
}

Where input could be this.may.have.number4.com and return 4

I was receiving error from above answer (probably due to my Jenkins version) - For some reason I get this: java.lang.UnsupportedOperationException: spread not yet supported in input.findAll(\d+)*.toInteger() ---- And it says on Jenkins its resolved.

Hope this helps.

answered Jan 15, 2019 at 18:16

hiquetj

4201 gold badge8 silver badges25 bronze badges

2 Comments

Trebla Over a year ago

Upvoted because, while it doesn't answer the exact question, provides a nice simple sub-case

gaoithe Over a year ago

replaceAll and replace with space if you want to parse multiple integers. e.g. input.replaceAll("[^0-9][^0-9]*", " ")

Abdennour TOUMI · Accepted Answer · 2013-09-14 09:05:44Z

After adding the method below ,numbersFilter,via metaClass , you can call it as following :

assert " i am a positive number 14".numbersFilter() == [ 14 ]
assert " we 12 are 20.3propaged 10.7".numbersFilter() == [ 12,20.3,10.7 ]
assert " we 12 a20.3p 10.7 ,but you can select one".numbersFilter(0) == 12
assert " we 12 a 20.3 pr 10.7 ,select one by index".numbersFilter(1) == 20.3

Add this code As BootStrap

String.metaClass.numbersFilter={index=-1->
            def tmp=[];
            tmp=delegate.findAll( /-?\d+\.\d*|-?\d*\.\d+|-?\d+/ )*.toDouble()
            if(index<=-1){
                return tmp;
            }else{
                if(tmp.size()>index){
                    return tmp[index];
                }else{
                   return tmp.last();
                }
            }

}

Mariusz · Accepted Answer · 2020-11-30 14:46:12Z

2

Since input.findAll( /\d+/ )*.toInteger() doesn't work with Jenkins. You can use this instead.

def packageVersion = "The package number is 9.2.5847.1275"
def nextversion=packageVersion.findAll( /\d+/ ).collect{ "$it".toInteger() }
nextversion.add(nextversion.pop()+1)
nextversion = nextversion.join('.')
Result: 9.2.5847.1276

answered Nov 30, 2020 at 14:46

Mariusz

3953 silver badges8 bronze badges

Comments

Catalin · Accepted Answer · 2020-11-30 17:54:47Z

0

Another alternative solution, without RegEx. It parses the string into tokens and convert them into a list of numbers or null values. The null values are removed and finally, only first entry is considered (as required).

def extractNumericData(String response) {
    response.split(' ')
        .collect { it.isFloat() ? Float.parseFloat(it) : null }
        .findAll { it }
        .first()
}

assert 100 == extractNumericData("100 pounds")
assert 173 == extractNumericData("I think 173 lbs")
assert 73 == extractNumericData("73 lbs.")

answered Nov 30, 2020 at 17:54

Catalin

4843 silver badges8 bronze badges

Comments

gaoithe · Accepted Answer · 2020-01-09 18:36:20Z

-1

When parsing line by line a String.contains and String.replaceAll (replace all sequences of non-digit chars with a space) then String.split() combination is useful, like this:

if (line.contains("RESULT:")) {
    l = line.replaceAll("[^0-9][^0-9]*"," ")
    a = l.split()
    pCount1 = Integer.parseInt(a[0])
    pCount2 = Integer.parseInt(a[1])
}

The String.findAll solutions are better! Equivalent:

if (line.contains("RESULT:")) {
    a = line.findAll( /\d+/ )*.toInteger()
    pCount1 = a[0]
    pCount2 = a[1]
}

answered Jan 9, 2020 at 18:36

gaoithe

4,4083 gold badges33 silver badges39 bronze badges

Collectives™ on Stack Overflow

Extract numeric data from string in groovy

6 Answers 6

2 Comments

2 Comments

Comments

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

6 Answers 6

2 Comments

2 Comments

Comments

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related