create node with name from another node

Question

I'm very new to XSLT, and I'd like to know how to create a node based on the text of another node. For example, if have the XML:

<axis pos="6" values="3">
  <title>Device</title>
  <label code="7">Autologous Tissue Substitute</label>
  <label code="J">Synthetic Substitute</label>
  <label code="K">Nonautologous Tissue Substitute</label>
</axis>

I'd like to transform it into:

<stuff>
  <Device pos="6" code="7">Autologous Tissue Substitute</Device>
  <Device pos="6" code="J">Synthetic Substitute</Device>
  <Device pos="6" code="K">Nonautologous Tissue Substitute</Device>
</stuff>

I've tried the following XSLT, but it just spews errors at me:

<xsl:template match="axis">
  <stuff>
    <xsl:apply-templates select="label" />
  </stuff>
</xsl:template>
<xsl:template match="label">
  <xsl:element name="{../title}">
    <xsl:value-of select="text()" />
  </xsl:element>
  <xsl:attribute name="pos">
    <xsl:value-of select="../@pos" />
  </xsl:attribute>
  <xsl:attribute name="code">
    <xsl:value-of select="@code" />
  </xsl:attribute>
</xsl:template>

Your requested output is invalid: you need to have a root element. — michael.hor257k
– michael.hor257k, Commented Mar 30, 2014 at 23:07
It's not about being pedantic (although it helps when you're dealing with code), it's about understanding what you're after. XSLT is very much context-dependent. Context issues are the reason why your attempt won't work: you have placed the attributes outside the <xsl:element> element. Place them inside (before the <xsL:value-of> element) and it will work. — michael.hor257k
– michael.hor257k, Commented Mar 30, 2014 at 23:31

Michael Kay · Accepted Answer · 2014-03-31 08:12:17Z

1

I would do:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="axis">
  <stuff>
    <xsl:apply-templates select="label" />
  </stuff>
</xsl:template>

<xsl:template match="label">
  <xsl:element name="{../title}">
    <xsl:copy-of select="@code | ../@pos" />
    <xsl:value-of select="." />
  </xsl:element>
</xsl:template>

</xsl:stylesheet>

answered Mar 31, 2014 at 8:12

Michael Kay

165k11 gold badges97 silver badges173 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

michael.hor257k · Accepted Answer · 2014-03-30 23:16:03Z

0

How about:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/">
    <root>
        <xsl:for-each select="axis/label">
            <xsl:element name="{../title}">
                <xsl:attribute name="pos">
                    <xsl:value-of select="../@pos" />
                </xsl:attribute>
                <xsl:attribute name="code">
                    <xsl:value-of select="@code" />
                </xsl:attribute>
                <xsl:value-of select="." />
            </xsl:element>
        </xsl:for-each>
    </root>
</xsl:template>

</xsl:stylesheet>

answered Mar 30, 2014 at 23:16

michael.hor257k

118k6 gold badges36 silver badges55 bronze badges

3 Comments

michael.hor257k Over a year ago

@JoeNahmias What am I looking at there?

JoeNahmias Over a year ago

click Run, then view source in the output pane

michael.hor257k Over a year ago

@JoeNahmias The input there is not the input here (apropos pedantic...)

JoeNahmias · Accepted Answer · 2014-03-30 23:48:04Z

0

This seems to work:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes" />
<xsl:template match="/root">
  <xsl:apply-templates select="axis" />
</xsl:template>
<xsl:template match="axis">
  <stuff>
    <xsl:apply-templates select="label" />
  </stuff>
</xsl:template>
<xsl:template match="label">
  <xsl:element name="{../title}">
    <xsl:attribute name="pos">
      <xsl:value-of select="../@pos" />
    </xsl:attribute>
    <xsl:attribute name="code">
      <xsl:value-of select="@code" />
    </xsl:attribute>
    <xsl:value-of select="." />
  </xsl:element>
</xsl:template>
</xsl:stylesheet>

answered Mar 30, 2014 at 23:48

JoeNahmias

3051 silver badge9 bronze badges

1 Comment

michael.hor257k Over a year ago

Your first template doesn't do anything (given the input here). You can delete it and it will keep working. BTW, most of us tend to put an empty line between templates to increase readability.

Collectives™ on Stack Overflow

create node with name from another node

3 Answers 3

Comments

3 Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

3 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related