Parser for JSON String

Question

I'm trying to write a parser for a JSON String.

A valid example, per my parser, would be: "\"foobar\"" or "\"foo\"bar\"".

Here's what I attempted, but it does not terminate:

parseEscapedQuotes :: Parser String
parseEscapedQuotes = Parser f
  where
    f ('"':xs) = Just ("\"", xs)
    f _        = Nothing

parseStringJValue :: Parser JValue
parseStringJValue = (\x -> S (concat x)) <$> 
         ((char '"') *> 
         (zeroOrMore (alt parseEscapedQuotes (oneOrMore (notChar '"')))) 
         <* (char '"'))

My reasoning is that, I can have a repetition of either escaped quotes "\"" or characters not equal to ".

But it's not working as I expected:

ghci> runParser parseStringJValue "\"foobar\""
Nothing

What is (zeroOrMore (alt parseEscapedQuotes (oneOrMore (notChar '"')))) supposed to do? What is alt? Why not just zeroOrMore (notChar '"')? — user2407038
– user2407038, Commented Feb 18, 2015 at 4:54

ErikR · Accepted Answer · 2015-02-18 16:24:24Z

1

I don't know what parser combinator library you are using, but here is a working example using Parsec. I'm using monadic style to make it clearer what's going on, but it is easily translated to applicative style.

import Text.Parsec
import Text.Parsec.String

jchar :: Parser Char
jchar = escaped <|> anyChar

escaped :: Parser Char
escaped = do
  char '\\'
  c <- oneOf ['"', '\\', 'r', 't' ] -- etc.
  return $ case c of
            'r' -> '\r'
            't' -> '\t'
            _   -> c

jstringLiteral :: Parser String
jstringLiteral = do
  char '"'
  cs <- manyTill jchar (char '"') 
  return cs

test1 = parse jstringLiteral "" "\"This is a test\""
test2 = parse jstringLiteral "" "\"This is an embedded quote: \\\" after quote\""
test3 = parse jstringLiteral "" "\"Embedded return: \\r\""

Note the extra level of backslashes needed to represent parser input as Haskell string literals. Reading the input from a file would make creating the parser input more convenient.

The definition of the manyTill combinator is:

manyTill p end      = scan
  where
    scan  = do{ end; return [] }
            <|>
            do{ x <- p; xs <- scan; return (x:xs) }

and this might help you figure out why your definitions aren't working.

answered Feb 18, 2015 at 16:24

ErikR

52.2k9 gold badges78 silver badges136 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Kevin Meredith Over a year ago

What's the meaning of char '\\' in escaped? PS - It's a custom parser library that I'm working on.

Kevin Meredith Over a year ago

also, my initial problem was that zeroOrMore has type Parser a -> Parser [a]. I was trying to call <|> (zeroOrMore (notQuote)) escaped, but it was not working as expected: runParser parseStringJValue "\"fo\"obar\"" === Just (S "fo","obar\"")

ErikR Over a year ago

The char function recognizes a single charater, e.g. char 'x' recognizes the character 'x'. The character literal '\\' is how you represent the backslash character.

ErikR Over a year ago

So an escaped character sequence is a backslash character followed by a double-quote, backslash, the letter 'r' or the letter 't' - and that's what the escaped parser recognizes.

Collectives™ on Stack Overflow

Parser for JSON String

1 Answer 1

4 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

4 Comments

Your Answer

Sign up or log in

Post as a guest

Related