Fortran function variable length string return

Question

I am writing a function to return a string

function doc () Result s
character (Len=65) :: s
...
end function

Is it possible to have a variable length string, where I can allocate the length of the string being returned. I know I can do it using a subroutine, but not for a function.

Function discl (nm) Result (s)

Character (Len=:), Allocatable :: s 
Character (Len=*), Intent (In) :: nm

Integer :: n
Character (Len=65) :: stamp
stamp = "Thu May  7 15:13:48 BST 2015" 

n = Len_trim (stamp)
Allocate (Character (n) :: s)
s = Trim (fstamp) 

End Subroutine discl

Yes, it is possible to return an allocatable function result, even a character with deferred length. Without seeing your attempts I can't tell what's going wrong for you. — francescalus
– francescalus, Commented May 7, 2015 at 14:06

Vladimir F Героям слава · Accepted Answer · 2015-05-07 14:11:00Z

8

It is the same for a subroutine and for a function. Only the header differs, but you can use the result variable as any other variable. My favourite example is the conversion of an integer to a string

  function itoa(i) result(res)
    character(:),allocatable :: res
    integer,intent(in) :: i
    character(range(i)+2) :: tmp
    write(tmp,'(i0)') i
    res = trim(tmp)
  end function

the result variable is allocated on assignment. You could use an allocate statement before the assignment, but that is redundant.

answered May 7, 2015 at 14:11

Vladimir F Героям слава

60.7k4 gold badges82 silver badges131 bronze badges

Sign up to request clarification or add additional context in comments.

9 Comments

Alexander Vogt Over a year ago

I disagree with your last statement. In my experience, allocation by assignment is asking for trouble! You should always allocate before an assignment and deactivate that particular feature at compile-time.

Vladimir F Героям слава Over a year ago

I don't bother, it is standard conforming the same way as automatic deallocation from F95 and even Intel is thinking about making it the default.

Zeus Over a year ago

What sort of problems have you encountered when you don't allocate?

Vladimir F Героям слава Over a year ago

@Zeus See stackoverflow.com/questions/23618034/…

Alexander Vogt Over a year ago

If you accidentally assign an array with mismatching shape you will not get an error message but the array will silently get re-allocated. This makes de-bugging very tricky.

|

Alexander Vogt · Accepted Answer · 2015-05-07 14:10:36Z

7

You can use allocatable strings for this purpose:

module str_mod
  implicit none

contains 

function str2str(str) result(s)
  implicit none
  character(len=*),intent(in)   :: str
  character(len=:),allocatable  :: s

  allocate( character(len=2*len(str)) :: s )
  s = str // str
end function

end module

program test
  use str_mod
  print *,str2str('test')
end program

answered May 7, 2015 at 14:10

Alexander Vogt

18.2k13 gold badges56 silver badges72 bronze badges

1 Comment

francescalus Over a year ago

Even with the discussion about the merits of the allocate statement in another answer, it's a good reminder how to allocate a deferred length character.

Collectives™ on Stack Overflow

Fortran function variable length string return

2 Answers 2

9 Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

9 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related