Using multiple else if statements

Question

I was trying to make a calculator in VBScript to test my skill, but came across an error. My program uses multiple else if statement to test what the user has input.

Here is my code below:

Dim head
Dim msg1, msgErr, msgAns
Dim input1, num1, num2
Dim ans

head = "Calculator"

msg1 = msgBox("Ruan's Vbscript calculator",0,head)
input1 = inputBox("How do you want to calculate? You can type (+ - * /)",head)

num1 = inputBox("Enter your first number",head)
num2 = inputBox("Enter your second number",head)

if (input1 = vbcancel) then
    wscript.quit()
else if (input1 = "+") then
    ans = num1 + num2
else if (input1 = "-") then
    ans = num1 - num2
else if (input1 = "*") then
    ans = num1 * num2
else if (input1 = "/") then
    ans = num1 / num2
else
    msgErr = msgBox("Make sure you type '+' or '-' or '*' or '/' with no extra letter or spaces","Error")
end if

msgAns = msgBox "Your answere is: " + head

When I run the program, the error says: "Expected end of statement". I don't see the problem here, as I have end if after all those else if statements.

I believe the correct syntax in VBScript is ElseIf w3schools.com/vbscript/vbscript_conditionals.asp — Wyatt Earp
– Wyatt Earp, Commented Jun 1, 2015 at 11:49
Any of the upvoters willing to explain why a calculator that claims that 5+7 is 57 deserves points? — Ekkehard.Horner
– Ekkehard.Horner, Commented Jun 1, 2015 at 12:22

Ansgar Wiechers · Accepted Answer · 2015-06-01 11:59:10Z

5

Remove the space between else and if and make it elseif. Like this:

if (input1 = vbcancel) then
    wscript.quit()
elseif (input1 = "+") then
    ans = num1 + num2
elseif (input1 = "-") then
    ans = num1 - num2
elseif (input1 = "*") then
    ans = num1 * num2
elseif (input1 = "/") then
    ans = num1 / num2
else
    msgErr = msgBox("Make sure you type '+' or '-' or '*' or '/' with no extra letter or spaces","Error")
end if

With the additional space between else and if you start a new if statement nested in the else branch rather than continuing the first if statement. The nested if statements require end ifs of their own, which is why you're getting the error.

edited Jun 1, 2015 at 11:59

Ansgar Wiechers

202k27 gold badges286 silver badges363 bronze badges

answered Jun 1, 2015 at 11:50

Rahul Tripathi

173k33 gold badges292 silver badges341 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Ekkehard.Horner Over a year ago

input1 = vbcancel does not work as some may think.

Ekkehard.Horner · Accepted Answer · 2015-06-01 12:18:14Z

Minimal improvements to make it work:

Option Explicit

Dim head
Dim msg1, msgErr, msgAns
Dim input1, num1, num2
Dim ans

head = "Calculator"
msgBox "Ruan's Vbscript calculator", 0, head
input1 = inputBox("How do you want to calculate? You can type (+ - * /)",head)
If Not IsEmpty(input1) Then
   num1 = CDbl(inputBox("Enter your first number",head))
   num2 = CDbl(inputBox("Enter your second number",head))
   if     input1 = "+" then
      ans = num1 + num2
   elseif input1 = "-" then
      ans = num1 - num2
   elseif input1 = "*" then
      ans = num1 * num2
   elseif input1 = "/" then
      ans = num1 / num2
   elseif input1 = "\" then
      ans = num1 \ num2
   else
      msgErr = msgBox("Make sure you type '+' or '-' or '*' or '/' with no extra letter or spaces","Error")
   end if
   msgBox "Your answere is: " & ans
else
   msgBox "Aborted"
end if

Type and range checks for the operants left as execise.

Alex K. · Accepted Answer · 2015-06-01 11:55:36Z

0

A Select Case is usually a simpler/clearer construction for selecting operations based on a single variables value

Select Case input1
    Case vbCancel
        wscript.quit()
    Case "+"
        ans = num1 + num2
    Case "-"
        ans = num1 - num2
    Case "*"
        ans = num1 * num2
    Case "/", "\" '//multiples
        ans = num1 / num2
    Case Else
        msgBox "Make sure you type '+' or '-' or '*' or '/' with no extra letter or spaces", , "Error"
End Select

answered Jun 1, 2015 at 11:55

Alex K.

177k32 gold badges276 silver badges299 bronze badges

2 Comments

Ekkehard.Horner Over a year ago

Please reconsider Case "/", "\" '//multiples (misleading comment, real vs integer div).

Ekkehard.Horner Over a year ago

input1 = vbcancel does not work as some may think.

Collectives™ on Stack Overflow

Using multiple else if statements

3 Answers 3

1 Comment

Comments

2 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related