Windows Batch File can't use variable in for syntax

Question

I want to use a variable skip parameter in for loop, but it won't let me do it. Here is my code

@echo off
setlocal ENABLEDELAYEDEXPANSION

set /p testcase=<testcases.txt
set /a end=%testcase%*13

for /L %%P IN (1,13,%end%) DO (

    set skip=skip=%%P
    echo !skip!
    set vidx=0

    for /f "%skip%" %%A in (testcases.txt) do (
        set /a vidx=!vidx! + 1
        set var!vidx!=%%A
    )
)

Here skip is skip=1, but it doesn't skip any line. When I replace it with skip=1. then it works fine, but I want to skip variable no. of lines in each iteration. Please help.

Tried using that as well, it said "!skip!" was unexpected at this time." — DarkNemesis
– DarkNemesis, Commented Aug 9, 2015 at 11:31

npocmaka · Accepted Answer · 2015-08-09 11:13:05Z

3

I think with this logic the only option is a subroutine:

@echo off
setlocal ENABLEDELAYEDEXPANSION

set /p testcase=<testcases.txt
set /a end=%testcase%*13

for /L %%P IN (1,13,%end%) DO (

    set skip=skip=%%P
    echo !skip!
    set vidx=0
    call :innerFor %%P

)

exit /b 0

:innerFor
    for /f "skip=%~1" %%A in (testcases.txt) do (
        set /a vidx=!vidx! + 1
        set var!vidx!=%%A
    )
 exit /b 0

parametrization of FOR /F options is a little bit tricky.. Though I have no the content of your files I cant test if this works correctly .

answered Aug 9, 2015 at 11:13

npocmaka

57.8k19 gold badges162 silver badges199 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

DarkNemesis Over a year ago

The file is a simple one. The first line contains an integer T i.e. the no. of test cases. T test cases follows. Each test case has 13 lines containing one integer in each.

npocmaka Over a year ago

@DarkNemesis - it's because how FOR /F parses its options.1)The parameters/tokens are always (%%A) are always expanded even after delayed expansion variables.2) When the FOR meets a %% in batch file it takes it for a parameter/token definition which is with higher prio than options - which brokes the command. Looks like command line arguments are expanded before the FOR tokens so with subroutine it works.

Collectives™ on Stack Overflow

Windows Batch File can't use variable in for syntax

1 Answer 1

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related