Not an Array reference navigating XML::Simple structure

The default value for the KeyAttr option is

KeyAttr => [qw( name key id )]

That means that XML::Simple will convert

 [ { name => $name1, ... }, { name => $name2, ... }, ... ]

into

 { $name1 => { ... }, $name2 => { ... }, ... }

You could use the following option to the get the structure you expect.

KeyAttr => []

Don't forget to also provide the following option if you want your code to work when only one entry is present:

ForceArray => [qw( entry )]

The use of XML::Simple is discouraged, even by its own documentation.

XML::LibXML solution:

use XML::LibXML qw( );
my $parser = XML::LibXML->new();
my $doc = $parser->parse_file('data.xml');
for my $node ($doc->findnodes(
   '/config/entry/source-translation/static-ip/translated-address'
)) {
   print($node->textContent(), "\n");
}

As you stated $data->{entry} is not an array reference in your data structure; it is a hash reference.

Check the script below, it accesses the data in the hash:

#!/usr/bin/perl
use v5.10; use strict; use warnings;
use XML::Simple;

my $xml = new XML::Simple;
my $data = $xml->XMLin("data.xml");
for my $entry (keys %{$data->{entry}}){
  say $data->{entry}->{$entry}->{'source-translation'}->{'static-ip'}->{'translated-address'};
}

And as Сухой27 pointed out; if you'd use Data::Dumper you'd be able to see the data structure and you'd see the hash instead of your assumed array.

Here is your problem:

use XML::Simple;

XML::Simple misleads you. It isn't simple at all. Unless you have absolutely no choice (and you probably do - it isn't core) then using another parser gives less pain.

Like:

use XML::Twig;
print $_ -> trimmed_text,"\n" for  XML::Twig -> new -> parsefile ( 'data.xml') -> get_xpath ( '//translated-address');

expanded out that's more like:

use strict ;
use warnings;
my $twig = XML::Twig -> new;
$twig -> parsefile ( 'data.xml');
foreach my $entry ( $twig -> findnodes ('//entry'))  {
    print $entry -> first_child('source-translation') -> first_child('static-ip') -> first_child_text('translated-address');
}