unable to run remote ssh commands with expect script

Question

I am unable to run commands on remote host using expect script.It just logs in to the remote host and exits.Here is the code

#!/usr/bin/expect
set timeout 15
puts "connecting to the storage\n"
set user [lindex $argv 0]
set host [lindex $argv 1]
set pass "root123"
spawn ssh "$user\@$host"
expect {
"Password: " {
send "$pass\r"
sleep 1
expect {
"$ " {
  send "isi quota quotas list|grep ramesh\r" }
"$ " {
  send "exit\r" }

}
}
"(yes/no)? " {
send "yes\r"
expect {
"$ " { send "ls\r" }
"$ " { send "exit\r" }

"> " {}
}
}
default {
send_user "login failed\n"
exit 1
}
}

It only gets into the remote host and exits. [deep@host1:~]$ ./sshexpect user1 host2 connecting to the storage

spawn ssh user1@host2
Password:
host2$
[deep@host1:~]$

Is the syntax wrong? I am new to tcl scripting.

glenn jackman · Accepted Answer · 2016-03-28 13:42:39Z

1

Indentation would help a lot:

expect {
    "Password: " {
        send "$pass\r"
            sleep 1
            expect {
                "$ " { send "isi quota quotas list|grep ramesh\r" }
                "$ " { send "exit\r" }
            }
    }
    "(yes/no)? " {
        send "yes\r"
            expect {
                "$ " { send "ls\r" }
                "$ " { send "exit\r" }
                "> " {}
            }
    }
    default {
        send_user "login failed\n"
            exit 1
    }
}

The problem is here:

            expect {
                "$ " { send "isi quota quotas list|grep ramesh\r" }
                "$ " { send "exit\r" }
            }

You're matching the same pattern twice: I suspect expect is ignoring the first action block, and just using the 2nd one; thus you exit immediately.

This is what you want to do:

expect {
    "(yes/no)? " { send "yes\r"; exp_continue }
    "Password: " { send "$pass\r"; exp_continue }
    timeout      { send_user "login failed\n"; exit 1 }
    -re {\$ $}
}
send "isi quota quotas list|grep ramesh\r"

expect -re {\$ $}
send "ls\r"

expect -re {\$ $}
send "exit\r"

expect eof

answered Mar 28, 2016 at 13:42

glenn jackman

249k42 gold badges233 silver badges362 bronze badges

Sign up to request clarification or add additional context in comments.

5 Comments

anudeep Over a year ago

I understood the mistake, but I didnt get what does the below line stands for -re {\$ $} And also why do we need to put expect eof at the end of the script

glenn jackman Over a year ago

The -re option uses regular expression pattern instead of the default glob patterns. I'm specifying that the prompt is a dollar sign and a space at the end of the line. If expect sees a dollar sign and a space and then some other text, that won't match as a prompt. expect eof basically means "wait until the spawned process is closed" -- not strictly necessary here, but generally good practice.

anudeep Over a year ago

I tried that still doesnt work for me.It shows the "login failed" and exits. It just logs into the remote box and then blank and after sometime exits with "login failed"

glenn jackman Over a year ago

run your script with expect -d filename to enable debug output. expect will tell you why none of the patterns match.

anudeep Over a year ago

I got it! Works for me now

Collectives™ on Stack Overflow

unable to run remote ssh commands with expect script

1 Answer 1

5 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

5 Comments

Your Answer

Sign up or log in

Post as a guest

Related