Passing function's data to another function

Question

How can I pass the data generated by the EliminaAcentos function to the URLEncode function in this script?

The first function removes diacritics and the second function URL-encodes the data.

Function EliminaAcentos(texto)
    Dim i, s1, s2
    s1 = "ÀÁÂÃÄÅÇÈÉÊËÌÍÎÏÒÓÔÕÖÙÚÛÜàáâãäåçèéêëìíîïòóôõöùúûü"
    s2 = "AAAAAACEEEEIIIIOOOOOUUUUaaaaaaceeeeiiiiooooouuuu"
    If Len(texto) <> 0 Then
        For i = 1 To Len(s1)
            texto = Replace(texto, Mid(s1,i,1), Mid(s2,i,1))
        Next
    End If

    EliminaAcentos = texto
End Function

Function URLEncode(ByVal str)
    Dim strTemp, strChar
    Dim intPos, intASCII
    strTemp = ""
    strChar = ""

    For intPos = 1 To Len(str)
        intASCII = Asc(Mid(str, intPos, 1))
        If intASCII = 32 Then
            strTemp = strTemp & "+"
        ElseIf ((intASCII < 123) And (intASCII > 96)) Then
            strTemp = strTemp & Chr(intASCII)
        ElseIf ((intASCII < 91) And (intASCII > 64)) Then
            strTemp = strTemp & Chr(intASCII)
        ElseIf ((intASCII < 58) And (intASCII > 47)) Then
            strTemp = strTemp & Chr(intASCII)
        Else
            strChar = Trim(Hex(intASCII))
            If intASCII < 16 Then
                strTemp = strTemp & "%0" & strChar
            Else
                strTemp = strTemp & "%" & strChar
            End If
        End If
    Next

    URLEncode = strTemp
End Function

WScript.Echo URLEncode(WScript.Arguments(0))

URLEncode( EliminaAcentos( WScript.Arguments(0))) but ensure that EliminaAcentos function declaration should be Function EliminaAcentos( ByVal texto) — JosefZ
– JosefZ, Commented Jun 19, 2016 at 20:33
I put this in the end of the script, but is not working (I did the ByVal texto) too. Wscript.Echo URLEncode( EliminaAcentos( WScript.Arguments(0))) — user2707722
– user2707722, Commented Jun 19, 2016 at 21:36

Community · Accepted Answer · 2017-05-23 10:33:58Z

1

Basically there are two ways to go about it:

You can nest the call of EliminaAcentos in the call of URLEncode as @JosefZ suggested:
```
URLEncode(EliminaAcentos(WScript.Arguments(0)))
```

You can embed the call of EleminaAcentos in the body of the URLEncode function:

Function URLEncode(ByVal str)
    Dim strTemp, strChar
    Dim intPos, intASCII
    strTemp = ""
    strChar = ""

    str = EliminaAcentos(str)
    For intPos = 1 To Len(str)
        ...
    Next

    URLEncode = strTemp
End Function

Usually you'd pick the first option if there are situations where you call URLEncode and don't want diacritics removed, or if you don't control the implementation of URLEncode. If you always want URLEncode to remove diacritics and you control the function implementation you'd pick the second option.

Side note (also mentioned by @JosefZ): pass the parameter to EliminaAcentos by value, so the function call doesn't inadvertently modify the original value.

Function EliminaAcentos(ByVal texto)
    ...
End Function

edited May 23, 2017 at 10:33

CommunityBot

11 silver badge

answered Jun 19, 2016 at 22:25

Ansgar Wiechers

202k27 gold badges286 silver badges363 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

user2707722 Over a year ago

Thanks so much for your help ! I´m using your second example (embed call), and it´s working fine :-)

Collectives™ on Stack Overflow

Passing function's data to another function

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related