Perl: Capturing correct return value from 'system' command

Question

I'm a beginner in Perl. I have a Windows batch script which contains multiple NMake commands. An existing issue with this batch script is that even if the NMake command fails during its execution, ERRORLEVEL doesn't get set properly.

So we never know whether the command worked until we parse the log file. I looked into it but couldn't find a solution. I, then thought of converting this batch script to a Perl script assuming that trapping error will be easier but it seems it's not that easy :)

Whenever I run my Perl script, the 'system' command always returns 0. I looked at many different links, and realized that capturing the correct return status of 'system' command is not that straightforward. Still, I tried the suggestions but things are not working. :(

Let me mention that the NMake command that is called, in turn, calls many different commands during its execution. For instance, the command output mentioned below, which is throwing 'fatal error', is actually part of a Perl script (check_dir.pl). This call to Perl script is written in the NMake file itself.

If I call this Perl file (check_dir.pl) directly and check for exit value, I get correct result i.e., the command fails and prints a non-zero exit value (...unexpectedly returned exit value 2).

Tried Perl's system function but it didn't help. I used the following code:

system ("nmake /f _nt.mak pack_cd SUB_PLAT=$PLAT DR=$plat 2>&1");

if ( $? == -1 ) {
    print "Command failed to execute: $!\n";
}
elsif ( $? & 127 ) {
    printf "The child died with signal %d, %s a coredump\n",
    ( $? & 127 ), ( $? & 128 ) ? 'with' : 'without';
}
else {
    printf "child exited with value %d\n", $? >> 8;
}

Output:

.....  
.....  
Unable to open dir: R:\TSM_Latest  
Compressing...NMAKE : fatal error U1077: 'if' : return code '0x2'  
Stop.  
child exited with value 0

Also tried:

use IPC::System::Simple qw(system);  
my $exit_status = system ("nmake /f _nt.mak pack_cd SUB_PLAT=$PLAT DR=$plat 2>&1");

if ($exit_status != 0) {  
    print "Failure";  
    exit 3;  
} else {  
    print "Success";  
}

Finally tried the following module:

use IPC::Run qw( run timeout );  
run "nmake /f _nt.mak pack_cd SUB_PLAT=$PLAT DR=$plat 2>&1" or die "NMake returned $?";

Nothing seems to be working :(

Please correct me if i'm interpreting the return value of system incorrectly.

Sinan Ünür · Accepted Answer · 2012-05-05 22:52:19Z

8

You have:

use IPC::System::Simple qw(system);
my $exit_status = system ("nmake /f _nt.mak pack_cd SUB_PLAT=$PLAT DR=$plat 2>&1");

Given that you don't seem to care about the actual output, you can try

my $exit_status = systemx(nmake => 
                              qw(/f _nt.mak pack_cd),
                              "SUB_PLAT=$PLAT",
                              "DR=$plat",
                          );

To make sure you bypass cmd.exe and see if you get something useful.

For reference, the exit codes from nmake are listed here.

Running the following program:

use strict; use warnings;

use IPC::System::Simple qw(systemx);
use Try::Tiny;

my $status = 0;

try   { systemx nmake => qw(/f bogus) }
catch { ($status) = ( /exit value ([0-9])/ ) };

print "Failed to execute nmake. Exit status = $status\n";

produces:

NMAKE : fatal error U1052: file 'bogus' not found
Stop.
Failed to execute nmake. Exit status = 2

The following version:

use strict; use warnings;

my $status = system nmake => qw(/f bogus);

if ($status) {
    if ($? == -1) {
        print "failed to execute: $!\n";
    }
    elsif ($? & 127) {
        printf "child died with signal %d, %s coredump\n",
        ($? & 127), ($? & 128) ? 'with' : 'without';
    }
    else {
        printf "child exited with value %d\n", $? >> 8;
    }
}

produces:

NMAKE : fatal error U1052: file 'bogus' not found
Stop.
child exited with value 2

In fact, even when I use

my $status = system "nmake /f bogus";

I get the same correct and expected output.

Ditto when I use

my $status = system "nmake /f bogus 2>&1";

These observations lead me to the following questions:

Which version of nmake are you using?
Is the /I option in effect? Even though you don't set it from the command line, note the following:

/I Ignores exit codes from all commands. To set or clear /I for part of a makefile, use !CMDSWITCHES. To ignore exit codes for part of a makefile, use a dash (–) command modifier or .IGNORE. Overrides /K if both are specified.

So, I put together the following files:

C:\temp> cat test.mak
test.target: bogus.pl; perl bogus.pl

C:\temp> cat bogus.pl
exit 1;

And, ran:

use strict; use warnings;

my $status = system "nmake /f test.mak 2>&1";

if ($status) {
    if ($? == -1) {
        print "failed to execute: $!\n";
    }
    elsif ($? & 127) {
        printf "child died with signal %d, %s coredump\n",
        ($? & 127), ($? & 128) ? 'with' : 'without';
    }
    else {
        printf "child exited with value %d\n", $? >> 8;
    }
}

which gave me the output:

        perl bogus.pl
NMAKE : fatal error U1077: 'c:\opt\perl\bin\perl.EXE' : return code '0x1'
Stop.
child exited with value 2

where the last line shows that the exit status of nmake was correctly propagated.

Conclusion:

You have some other problem.

In fact, the OP later pointed out in comments that:

The actual command that i am trying to run is: system ("nmake /f _nt.mak pack_cd SUB_PLAT=$PLAT DR=$plat 2>&1 | C:\\tee2 $TEMP_DIR\\modules-nt_${platlogfile}");

Given tees involvement in the pipeline, it is not surprising that nmakes exit code gets lost. tee is successfully able to process output from nmake, so it returns success, and that's the exit code your script sees.

Therefore, the solution is to capture the output of nmake yourself, either using qx (coupled with the appropriate level of error checking), or using capture from IPC::System::Simple. Then, you can decide to whether you want to print that output, save to a file, put it in an email etc …

edited May 5, 2012 at 22:52

answered May 4, 2012 at 22:50

Sinan Ünür

118k15 gold badges201 silver badges347 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Technext Over a year ago

Thank You for all your help Sinan! The first systemx code that you asked me to test (bypassing cmd.exe) worked fine. However, it was then when i realized what i did. The actual command that i am trying to run is: system ("nmake /f _nt.mak pack_cd SUB_PLAT=$PLAT DR=$plat 2>&1 | C:\\tee2 $TEMP_DIR\\modules-nt_${platlogfile}"); and not system ("nmake /f _nt.mak pack_cd SUB_PLAT=$PLAT DR=$plat 2>&1"); Yesterday, I advertently removed the logging portion ('pipe') thinking that i should only post the relevant code. I'm really sorry for that Sinan! :(

Technext Over a year ago

It seems the tee command was always a success so the return value was always 0. Am i right? Now, when i run my original command using 'system', it works as expected:

use IPC::System::Simple qw(system); system ("nmake /f _nt.mak pack_cd SUB_PLAT=$PLAT DR=$plat > $TEMP_DIR\\modules-nt_${platlogfile}");

Now the only problem i'm facing is that i don't see any console output because everything is getting redirected to the file. Any help in this regard?

Znik Over a year ago

you can tail log file by separate perl process or thread. I don't know it is possible in easy way on windows.

Collectives™ on Stack Overflow

Perl: Capturing correct return value from 'system' command

1 Answer 1

Conclusion:

3 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Conclusion:

3 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related