Simulate while loop in Batch

Question

I'm trying to simulate a while loop in Batch, here's my code:

@echo off
set test=0

:main
call:whileLSS %test% 4 :count

:whileLSS
if %1 LSS %2 (
    echo %1
    call%3
    goto whileLSS
)
goto:EOF

:count
set /a test=%test%+1
goto:EOF

This just outputs 0s, instead of outputting "0 1 2 3" like I want it to.

The problem is that the loop goes forever because %1 doesn't have the most updated value of test.

Is this the right approach?

How do I update the value of %1?

Is there a way to not have to hardcode operators like LSS?

You can't update the value of a command line argument. You would have to assign it to an environmental variable first and then update it. — Squashman
– Squashman, Commented Dec 1, 2016 at 20:22
Related: while loop in batch and how to do a while loop on batch — aschipfl
– aschipfl, Commented Dec 1, 2016 at 20:25

score 3 · Accepted Answer · 2016-12-01 22:02:17Z

3

as you've been told, you can't change an Arg, you can take the arg as a reference and change the referenced var, this requires delayed expansion here.
Your first sub also wasn't separated from flow.

This Batch:

@echo off&Setlocal EnableDelayedExpansion
set test=0

:main
call:whileLSS test 4 :count
Goto :Eof

:whileLSS
if !%1! LSS %2 (
    echo !%1!
    call%3
    goto whileLSS
)
goto:EOF

:count
set /a test+=1
goto:EOF

Produces this output:

Edit
The operator to the if may also be suppied as an arg:

@echo off&Setlocal EnableDelayedExpansion
set test=0

:main
call:while test LSS 4 :Increment
set test=10
call:while test GTR 4 :Decrement

Goto :Eof
:while
if !%1! %2 %3 (
    echo !%1!
    call %4 %1
    goto while
)
goto:EOF

:Increment
set /a %1+=1
goto:EOF

:Decrement
set /a %1-=1
goto:EOF

edited Dec 1, 2016 at 22:02

answered Dec 1, 2016 at 20:50

user6811411

Sign up to request clarification or add additional context in comments.

4 Comments

Nihil Over a year ago

Is there a way to take another argument to use an operator? That way I don't have to make a while for LEQ, GTR and GEQ

user6811411 Over a year ago

@Nihil yes, just tested it, see append to the answer.

user6811411 Over a year ago

@Nihil Did another edit to the subs, but I now feel a bit vrtualized ;-) And I personally prefer straight code I still understand a year later.

Nihil Over a year ago

strange, for some reason when I tried having a fourth argument it always had the value of "4", now it works :)

Ushakov Mikhail · Accepted Answer · 2016-12-01 20:31:21Z

0

Like this may be?

@echo off

:main
set /a a=1
set /P i=Enter i:
call:whileLSS %a% %i%

:whileLSS
    echo %1
    if %1 LSS %2  call:reinitialize %1 %2
    goto:EOF


:reinitialize
    set /a c=%1
    set /a b=%c%+1
    set /a d=%2
    call:whileLSS %b% %d%

goto:EOF

answered Dec 1, 2016 at 20:31

Ushakov Mikhail

1

1 Comment

Jean-François Fabre Over a year ago

even if this seems to answer the question, it would be best to provide explanations on your code and on the OP code (why it didn't work, why your code does what's required)

Kirk Beard · Accepted Answer · 2016-12-09 10:25:01Z

0

Try this:

@echo off 
Setlocal EnableDelayedExpansion
set test=0

:main
call :whileLSS !test! 4 
Goto :Eof

:whileLSS
set i=%1
set j=%2

:loop
if !i! LSS !j! (
    echo !i!
    call :count
    goto :loop
)

goto :EOF

:count
set /a i+=1
goto :EOF

edited Dec 9, 2016 at 10:25

Kirk Beard

9,89312 gold badges45 silver badges48 bronze badges

answered Dec 2, 2016 at 1:00

Blake K Akiti

1732 gold badges3 silver badges10 bronze badges

Collectives™ on Stack Overflow

Simulate while loop in Batch

3 Answers 3

4 Comments

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

4 Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related