Update a userform listbox after userform initialization

Question

Is there any way to update a ListBox on a UserForm outside of the Userform_Initialize sub?

Why? I am building a blackjack game and using listboxes to tell the user what cards they have/ the dealer has. I was hoping to use a simple sub (ShowCards) to add items to the listboxes but I've run into problems:

The Play button calls the PlayBlackjack sub which sits in a normal module

Option Explicit

Dim cards As New Collection

Sub ShowGame()
    UFDisplay.Show
End Sub

Sub PlayBlackjack()
    'fill the cards collection with 5 shuffled decks
    PrepareCards

    Dim i As Integer
    Dim userHand As New Collection
    Dim dealerHand As New Collection

    'deal cards (removing the dealt cards from the cards collection)
    For i = 1 To 2
        DealCard cards, userHand
        DealCard cards, dealerHand
    Next i

    ShowCards userHand, UFDisplay.UserHandList <-- ERROR HERE (Type mismatch)

    'more code to follow
End Sub

Private Sub ShowCards(hand As Collection, list As ListBox)
    Dim i As Integer

    For i = 1 To hand.Count
        list.AddItem hand(i).CardName
    Next i
End Sub

Let me know if you think you need any more of the code. hand is a collection of card classes where .CardName returns something like 3 of Hearts

Everything I read seems to tell me that the userform is static after being initialized so I would need to refresh it in some way after adding the new items. I tried Userform.Repaint with no luck.

So if there really is no other way, should I declare userHand and dealerHand as global variables, update them and call Useform_Initialize to take the updated values and show them to the user? Given the nature of the game being that multiple more cards could be dealt for both players it doesn't seem sensible to be re-initializing the userform multiple times each game.

All suggestions welcome. If you think I should have done it completely differently I'd still be keen to hear (but not so interested in worksheet solutions)

Update #1 For clarity, ShowGame is called by a button on the workshet, then PlayBlackjack is called from the Play button on the Userform (nothing else in the userform code)

it will me me.userhandlist

Nathan_Sav
– Nathan_Sav

2016-12-12 17:04:24 +00:00
Commented Dec 12, 2016 at 17:04 — Nathan_Sav
– Nathan_Sav, Commented Dec 12, 2016 at 17:04

A.S.H · Accepted Answer · 2016-12-12 18:07:43Z

4

Ah, I see. You cannot declare the listBox parameter as ListBox. The latter is reserved for Activex controls, not VBA controls. Change the signature of your ShowCardssub into this:

Private Sub ShowCards(hand As Collection, list As Control) '<~~ or MSForms.ListBox, or simply as Object...

edited Dec 12, 2016 at 18:07

answered Dec 12, 2016 at 17:30

A.S.H

29.4k6 gold badges25 silver badges50 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

A.S.H Over a year ago

@CallumDA glad to help :)

Nathan_Sav · Accepted Answer · 2016-12-12 17:44:30Z

4

You could use a class for the hand also, and set the class listbox to be the form listbox, for example, the class clsHand

Public colHand As collection
Public lstToUpdate As MSForms.ListBox

Private Sub Class_Initialize()
    Set colHand = New collection
End Sub

Friend Function AddCard(card As clsCard)
    colHand.Add card, CStr(colHand.Count)
    If Not lstToUpdate Is Nothing Then
        lstToUpdate.AddItem card.strCardName
    End If
End Function

It's use in a form

Private clsPlayerHand As clsHand

Private Sub UserForm_Initialize()
    Set clsPlayerHand = New clsHand
    Set clsPlayerHand.lstToUpdate = Me.ListBox1
End Sub

Private Sub CommandButton1_Click()
    Dim clsC As New clsCard
    clsC.strCardName = "one"
    clsPlayerHand.AddCard clsC
End Sub

EDIT: Recommendation,

Use the numeric and the suit name for your cards, then you can do the following, say enabling the split button, incidentally, you'd use an array of hands then arrHands(x) ...

Public colHand As collection
Public lstToUpdate As MSForms.ListBox
Public cmdSplitButton As MSForms.CommandButton

Private Sub Class_Initialize()
    Set colHand = New collection
End Sub

Friend Function AddCard(card As clsCard)
    colHand.Add card, CStr(colHand.Count)
    If Not lstToUpdate Is Nothing Then
        lstToUpdate.AddItem card.CardName
    End If
    If Not cmdSplitButton Is Nothing Then
        If colHand.Count = 2 Then _
        cmdSplitButton.Enabled = colHand(1).NumericPart = colHand(2).NumericPart
    End If
End Function

Look at using classes to their full potential and look at events also, to react to certain things.

edited Dec 12, 2016 at 17:44

answered Dec 12, 2016 at 17:16

Nathan_Sav

8,5762 gold badges18 silver badges22 bronze badges

3 Comments

CallumDA Over a year ago

Thank you for this, I did start with a hand class too but I wasn't using it enough to feel like it was necessary - this is an interesting idea. I'm going to play around with it and see if it makes things much neater

CallumDA Over a year ago

Thanks again, this was a great suggestion - I tested it out and it worked really well. I think I'll post my final code on code review to see how close I get to something decent overall, your help was much appreciated. For now I accepted A.S.H's answer because I think it'll be most useful for other people.

Nathan_Sav Over a year ago

No worries, but the proper solution would be Public Sub subname(x As MSForms.ListBox) :) Have a good day.

Collectives™ on Stack Overflow

Update a userform listbox after userform initialization

2 Answers 2

1 Comment

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related