Combining array to get an array of hashes

Question

I have three arrays that need to be stored together for future use. Each array is related to each other, and every array element per position is meant to be matched together. The arrays elements orders will always be correct, but beyond that, there is no easy way to discern the correct order once lost.

How can I combine these arrays together without losing their original order?

I am assuming that an array of hashes is the best way to go, but, please let me know if I'm wrong in that assumption.

Example Arrays:

my @numbers = (5,2,7,32,9);
my @letters = qw(z b t t c);
my @words   = qw(tiny book lawn very dance);

Example end result.

my @combined_arrays = (
       {
           'number' => '5',
           'letter' => 'z',
           'word'   => 'tiny',
       },
       {
           'number' => '2',
           'letter' => 'b',
           'word'   => 'book',
       },
       {
           'number' => '7',
           'letter' => 't',
           'word'   => 'lawn',
       },
       {
           'number' => '32',
           'letter' => 't',
           'word'   => 'very',
       },
       {
           'number' => '9',
           'letter' => 'c',
           'word'   => 'dance',
       },
);

Why not use an array of arrays: my @combined_arrays = (\@numbers, \@letters, \@words ) ? or my @combined_arrays = ([@numbers], [@letters], [@words] ) if you need to make a copy... — Håkon Hægland
– Håkon Hægland, Commented Jul 2, 2018 at 19:47
Other than the shown hashes it may also be an array-of-arrays as ([5,'z','tiny'], ...), if you want to group them by position. For how to create either see this recent page (near duplicate). — zdim
– zdim, Commented Jul 2, 2018 at 19:58
I should have mentioned I wanted to pour this into a db at some point. I was thinking that the array of hashes would be easier to iterate over. — user3049982
– user3049982, Commented Jul 2, 2018 at 20:09
@user: There seems to be no reason to use hashes. If you know that the items are always in the order number, letter, word then there is no confusion. I also recommend an array of arrays for simplicity and economy of space. (Using hashes, you would be storing many many copies of the three strings 'number', 'letter', and 'word') — Borodin
– Borodin, Commented Jul 2, 2018 at 20:14
@user: Sure, but that answer shows how to build an array of hashes, which as I've said is unnecessary, very wasteful, and long-winded to process. I'm trying to address your "trouble breaking out of [the loop] and not creating duplicates". You should learn how to do this properly sooner rather than later, and not just accept the first example that works. — Borodin
– Borodin, Commented Jul 2, 2018 at 22:51

hoffmeister · Accepted Answer · 2018-07-02 20:02:03Z

4

I would do it like this

my @combined_arrays = map { "number" => $numbers[$_] , "letter" => $letters[$_] , "word" => $words[$_] } , 0..@letters-1;

answered Jul 2, 2018 at 20:02

hoffmeister

6124 silver badges10 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

user3049982 Over a year ago

I very much, made this more complicated than it needed to be. Thanks, that does it. :)

hoffmeister Over a year ago

NP, map is really handy for one liners where you need to iterate though a list. You could have also done this using a for loop and push each entry onto the array. However, this would take an extra line ;-)

beasy Over a year ago

@letters-1 == $#letters :)

elcaro · Accepted Answer · 2018-07-03 05:47:21Z

3

I realise you've already accepted an answer, but I thought I'd just throw out a more concise option that relies on some modules.

I'm using zip (aka mesh, from either List::SomeUtils or List::MoreUtils) and zip_by (from List::UtilsBy), but I'm importing both of them via List::AllUtils.

use strict;
use warnings;
use List::AllUtils qw( zip zip_by );

my @numbers = (5,2,7,32,9);
my @letters = qw(z b t t c);
my @words   = qw(tiny book lawn very dance);
my @keys    = qw(number letter word);

my @combined = zip_by { +{ zip @keys, @_ } } \@numbers, \@letters, \@words;

It's potentially more readable, but only if you're familiar with what zip and zip_by do. At the very least, it fits inside 80 characters.

Update I originally had \%{{ zip @keys, @_ }} inside the zip_by. This was to force it to interpret my curlies as a hash-ref. Then I remembered that +{} is a prettier way to disambiguate.

edited Jul 3, 2018 at 5:47

answered Jul 3, 2018 at 2:06

elcaro

2,31716 silver badges15 bronze badges

1 Comment

user3049982 Over a year ago

Thanks, this is helpful.

Collectives™ on Stack Overflow

Combining array to get an array of hashes

2 Answers 2

3 Comments

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

3 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related