Variable substring Edit/Replace inside a for loop

Question

I want to replace a variable's substring, previously stored on a variable inside a for loop, I tried to do it like this but it didn't work:

setlocal EnableDelayedExpansion
set checkVar=abcd
FOR %%Y IN (*.pdf) DO (  
    SET meu=%%Y
    CALL SET meuWithoutChar=!meu:%%%checkVar%%%=! 
    ECHO meuWithoutChar=!meuWithoutChar!
)

For example here if %%Y==blepabcdnnnn.pdf; I want to have meuWithoutChar=blepnnnn.pdf on the output Thank you in advance

You do not need to use that many percent symbol nor do you need to use the CALL if you are trying to use delayed expansion. The replace variable is outside the loop so you only need a single set of percent symbol. You are attempting to use delayed expansion but you have not enabled it with a SETLOCAL command. — Squashman
– Squashman, Commented Aug 4, 2018 at 17:14
While not required by syntax, proper indenting helps reading the code. — user6811411
– user6811411, Commented Aug 4, 2018 at 17:29
I wrote the question a little too fast, sorry I edited it to make it more clear — Blume
– Blume, Commented Aug 4, 2018 at 18:08

Squashman · Accepted Answer · 2018-08-04 17:21:06Z

2

You are bit confused on the concept of delayed expansion and the use of CALL to get an extra phase of expansion. Here are the examples. I am just using your single file example. You can change it back to using the wildcard.

CALL example

@echo off
set checkVar=abcd
FOR %%Y IN (blepabcdnnnn.pdf) DO (  
SET "meu=%%Y"
CALL SET "meuWithoutChar=%%meu:%checkVar%=%%" 
CALL ECHO meuWithoutChar=%%meuWithoutChar%%
)
pause

Delayed Expansion

@echo off
setlocal Enabledelayedexpansion
set checkVar=abcd
FOR %%Y IN (blepabcdnnnn.pdf) DO (  
SET "meu=%%Y"
SET "meuWithoutChar=!meu:%checkVar%=!" 
ECHO meuWithoutChar=!meuWithoutChar!
)
pause

answered Aug 4, 2018 at 17:21

Squashman

14.4k5 gold badges30 silver badges38 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Blume Over a year ago

Thank you! On my first try I tired CALL SET meuWithoutChar=!meu:%checkVar%=! , but it didn't work. Over the fact that the use of CALL wasn't necessary, I don't know where I messed it up. (sorry for mixing everithing up, I'm not used to code)

Compo · Accepted Answer · 2018-08-04 17:59:33Z

1

As a supplement/extension to Squashmans answer.
Only cycles through necessary files and ignores the file's extension.

Without delayed expansion:

@Echo Off
SetLocal DisableDelayedExpansion
Set "strChr=abcd"
For %%A In ("*%strChr%*.pdf") Do (Set "objFileName=%%~nA"
    Call Set "objNewFile=%%objFileName:%strChr%=%%%%~xA"
    Call Echo %%%%objNewFile%%%%=%%objNewFile%%)
Pause

With full script delayed expansion, (will have issues with filenames containing !'s):

@Echo Off
SetLocal EnableDelayedExpansion
Set "strChr=abcd"
For %%A In ("*%strChr%*.pdf") Do (Set "objFileName=%%~nA"
    Set "objNewFile=!objFileName:%strChr%=!%%~xA"
    Echo %%objNewFile%%=!objNewFile!)
Pause

With toggled delayed expansion, (protects filenames containing !'s):

@Echo Off
SetLocal DisableDelayedExpansion
Set "strChr=abcd"
For %%A In ("*%strChr%*.pdf") Do (Set "objFileName=%%~nA"
    SetLocal EnableDelayedExpansion
    Set "objNewFile=!objFileName:%strChr%=!%%~xA"
    Echo %%objNewFile%%=!objNewFile!
    EndLocal)
Pause

answered Aug 4, 2018 at 17:59

Compo

39k5 gold badges32 silver badges46 bronze badges

2 Comments

Blume Over a year ago

Thank you! If I understood, call command can always be used instead of the delayed expansion and reciprocally?

Compo Over a year ago

@Blumer, no it cannot. Whilst it may work in the specific case above, the Call command is not an alternative for enabling delayed expansion, (you can't Call If "%%objNewFile%%"=="efgh" ... for instance).

Collectives™ on Stack Overflow

Variable substring Edit/Replace inside a for loop

2 Answers 2

1 Comment

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related