Parsing embedded JSON with Aeson

Question

I'm trying to parse embedded JSON of the form

{
  "foo":"bar",
  "baz":"\{\"somekey\":\"someval\"\}"
}

with Aeson in Haskell. Here are my types:

data BaseType = BaseType { foo :: String, baz :: EmbeddedType } deriving(Show)

instance FromJSON BaseType where
  parseJSON = withObject "BaseType" $ \o -> do
    foo <- o .: "foo"
    baz <- o .: "baz"
    return $ BaseType { foo=foo, baz=baz }

data EmbeddedType = EmbeddedType { somekey :: String }

instance FromJSON EmbeddedType where
  parseJSON = withObject "EmbeddedType" $ \o -> do
    somekey <- o .: "somekey"
    return $ EmbeddedType {somekey=somekey}

Obviously, the FromJSON instance for BaseType doesn't work, since it sees it as a Value String instead of as more JSON for it to parse. I tried to find a way to use decodeEither in my FromJSON BaseType instance, but that required that I do some black magic to convert from String to ByteString, and I feel like there must be a neater way, possibly related to withEmbeddedJSON.

How can I make this work correctly?

Isn't this something that can be addressed with the standard DeriveGeneric mechanism of Aeson? — Mark Seemann
– Mark Seemann, Commented Dec 19, 2018 at 16:08
@MarkSeemann I'm not sure what that means and google isn't spitting out anything useful for "DeriveGeneric Aeson". Would you mind explaining or linking me somewhere? — thesecretmaster
– thesecretmaster, Commented Dec 19, 2018 at 16:11
@MarkSeemann I don't think this solves my issue. It still gives a "got String expected EmbeddedType" error. — thesecretmaster
– thesecretmaster, Commented Dec 19, 2018 at 16:19
That's not something that is addressed by aeson's deriving stuff. — Li-yao Xia
– Li-yao Xia, Commented Dec 19, 2018 at 16:32

Daniel Wagner · Accepted Answer · 2018-12-19 16:39:57Z

2

I guess it would be something like this (untested):

instance FromJSON BaseType where
  parseJSON = withObject "BaseType" $ \o -> do
    foo <- o .: "foo"
    bazText <- o .: "baz"
    baz <- withEmbeddedJSON "EmbeddedType" parseJSON (String bazText)
    return $ BaseType { foo=foo, baz=baz }

Or you could consider moving the call to withEmbeddedJSON into the EmbeddedType instance; then o .: "baz" should Just Work in the BaseType instance, at the cost of no longer having a handle onto a parser that just does EmbeddedType parsing without de-stringifying:

instance FromJSON BaseType where
  parseJSON = withObject "BaseType" $ \o -> do
    foo <- o .: "foo"
    baz <- o .: "baz"
    return $ BaseType { foo=foo, baz=baz }

instance FromJSON EmbeddedType where
  parseJSON = withEmbeddedJSON "EmbeddedType" . withObject "EmbeddedType" $ \o -> do
    somekey <- o .: "somekey"
    return $ EmbeddedType {somekey=somekey}

edited Dec 19, 2018 at 16:39

answered Dec 19, 2018 at 16:31

Daniel Wagner

156k10 gold badges231 silver badges392 bronze badges

Sign up to request clarification or add additional context in comments.

6 Comments

Li-yao Xia Over a year ago

you could do baz_ <- o .: "baz" and give baz_ type Text (aeson does decoding anyway). That would save the case HM.lookup .....

Li-yao Xia Over a year ago

I think you'll have to make an explicit call to decode in any case. (parseJSON still requires you to get a Value from somewhere)

Daniel Wagner Over a year ago

@Li-yaoXia withEmbeddedJSON calls decode for you (well, eitherDecode, anyway).

thesecretmaster Over a year ago

Thank you for your help, and the code works, but would you mind helping me out a bit by explaining a couple things? I'm kinda new to Haskell, and I don't understand 1) how you're composing withEmbeddedJSON with withObject, 2) Your use of the String type constructor, and 3) How passing parseJSON into withEmbeddedJSON does what we want it to.

Daniel Wagner Over a year ago

@thesecretmaster For (1) you might like this question; for (2) I looked at the source of withEmbeddedJSON to see what it expected as input; for (3) type inference selects parseJSON :: Value -> Parser EmbeddedType, so it dispatches to your other instance for parsing the embedded JSON.

|

Collectives™ on Stack Overflow

Parsing embedded JSON with Aeson

1 Answer 1

6 Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

6 Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related