Batch file searching for multiple file formats in FOR loop

Question

I'm coding a batch file that should search two folder paths for multiple file extensions and list them in a text file. Currently I'm trying to use a FOR loop with a list of file extensions (*.doc, *.docx, etc). I believe the file is erroring out because of the "*" character but I don't know how to correct this.

I've tried to straight list them: FOR %%G IN (*.one,*.mht,*.onepkg). I've tried quote marks: FOR %%G IN ("*.one","*.mht","*.onepkg"). I've tried carets: FOR %%G IN (^^*.one,^^*.mht,^^*.onepkg).

Here's my code:

set outputfilepath=d:\output.txt

FOR %%G IN ("*.one","*.mht","*.onepkg") DO (
echo Searching for %%G files
dir "C:\%%G" /s /b >> "%outputfilepath%"
Rem Add 2 blank lines between next search
echo. >> "%outputfilepath%"
echo. >> "%outputfilepath%" )

Nothing gets output to my text file.

Any help is appreciated.

What's wrong with simply using Where /R C:\ *.one *.mht *.onepkg > "D:\output.txt"? or Dir /B /S /A-D C:\*.one C:\*.mht > "D:\output.txt"? Of those two examples, the former will match the extensions exactly, the latter outputs extensions beginning with .one and .mht, (as does your current FOR loop), so will therefore output the .onepkg extensions too! — Compo
– Compo, Commented Jun 7, 2019 at 14:31
My only issue with that solution is that my supervisor would like something that displays on the screen "Searching for <extension> files" and formatting the output file with two spaces in between different lists of files found for readability. Would there be some way to do that with either of those commands? — Gunslinger711
– Gunslinger711, Commented Jun 7, 2019 at 15:38

Magoo · Accepted Answer · 2019-06-07 16:36:19Z

3

@ECHO Off
SETLOCAL
set "outputfilepath=u:\output.txt"

(
FOR %%G IN (one,mht,onepkg) DO (
 echo Searching for %%G files>con
 dir ".\*.%%G" /s /b |FINDSTR /i /e /L ".%%G"
 Rem Add 2 blank lines between next search
 echo. 
 echo.  
)
)> "%outputfilepath%"

GOTO :EOF

Please note that I've changed drivenames to suit my system.

simply for meta in extensionlist then add the * in the dir command. Filter the dir output using findstr to ensure that only names matching /e at the end /L the literal ".%%G" are shown.

Also by enclosing the enitre for command in parentheses, you can send all stdout text (which would normally appear on the console) to the file. > naturally means create-file-anew. >> to append if that's your preference.

The >con appended to the Searching... echo overrides the redirection and specifically sends the text from that echo to the console.

answered Jun 7, 2019 at 16:36

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

Señor CMasMas Over a year ago

Dear Mr. @Magoo... how on earth does your highlighting end up so pretty? I have been reading links for 20 minutes now and can't figure it out. :^P Most of the links said that it would figure it out based on the tags but isn't working for me.

Magoo Over a year ago

@SeñorCMasMas : see stackoverflow.com/help/formatting - simply insert  and a blank line directly before the code block.

Gunslinger711 Over a year ago

This is brilliant and exactly what I'm looking for. Magoo, you've done it again!

Magoo · Accepted Answer · 2019-06-07 17:10:43Z

I really like the existing suggestions but this is a different approach. I find that this style reads more like code.

This may seem very complicated but...

This technique can be used to loop over parameters for ANYTHING to include ones passed via the command line.
The logic of looping through passed parameters is isolated to its own function (enumerate_search_types).
The logic of what you are going to do with each parameter is isolated to its own function (search_for_search_type).

This might make it easier for some, too complicated for others.

@echo off

:: The parameters we are working with...
set outputfilepath=d:\output.txt
set starting_path=c:\
set search_types="*.one" "*.mht" "*.onepkg"

pushd "%starting_path%"
call :enumerate_search_types %search_types%
popd
goto :EOF

:: ---------------------------------------------------------------
:enumerate_search_types
set "current_param=%~1"
if "%current_param%"=="" goto :EOF
call :search_for_search_type "%current_param%"
shift /1
goto :enumerate_search_types

:: ---------------------------------------------------------------
:search_for_search_type
set "current_search_type=%1"
set "had_output=false"

echo Searching for %current_search_type% files
for /f "delims=" %%f in ('dir /s /b %current_search_type% 2^>NUL') do set had_output=true&& echo %%f >> "%outputfilepath%"

:: If the dir command didn't produce anything, don't add the blank lines
if "false"=="%had_output%" goto :EOF
echo. >> "%outputfilepath%"
echo. >> "%outputfilepath%"
goto :EOF

Dorian Grv · Accepted Answer · 2020-04-29 09:31:04Z

0

Short answer if you refer to only the file extension. In order to use different extension in a for loop:

FOR %%G IN (one,mht,onepkg) do [command]

answered Apr 29, 2020 at 9:31

Dorian Grv

4995 silver badges10 bronze badges

Collectives™ on Stack Overflow

Batch file searching for multiple file formats in FOR loop

3 Answers 3

3 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

3 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related