Parsing nested arrays in Aeson

Question

Im struggling to parse the below JSON using the Aeson library.
Im only interested in getting file1 but I cant seem to manage it.
Does anyone have suggestions?

The JSON

{"files":[["file1.wav",["file2.jpg","file3.jpg"]]]}

My code

data File = File Text deriving (Show, Generic, ToJSON)

instance FromJSON File where
  parseJSON jsn = do
    arrays <- parseJSON jsn
    let x = arrays !! 0 !! 0
    return $ File x

Error message

"Error in $.files[0][1]: parsing Text failed, expected String, but encountered Array"

Li-yao Xia · Accepted Answer · 2020-04-05 17:51:36Z

3

The problem is using parseJSON to parse jsn into a homogeneous list. But "file1.wav" is a string and ["file2.jpg", "file3.jpg"] is not a string.

A simple solution is to directly pattern-match on json, which is a Value which can contain a heterogeneous Array (in spite of its name, it's actually a synonym for a Vector from the vector library).

{-# LANGUAGE OverloadedStrings #-}
import Data.Aeson
import qualified Data.Vector as V
import Data.Text (Text)

newtype File = File Text deriving Show

instance FromJSON File where
  parseJSON json = do
    Array arr <- pure json
    Just (Array arr0) <- pure (arr V.!? 0)
    Just (String txt) <- pure (arr0 V.!? 0)
    pure (File txt)

main :: IO ()
main = print (decode' "[[\"file1\", [\"file2\", \"file3\"]]]" :: Maybe File)

((!?) is a safe indexing operator.)

edited Apr 5, 2020 at 17:51

answered Apr 4, 2020 at 15:28

Li-yao Xia

34.2k2 gold badges38 silver badges63 bronze badges

Sign up to request clarification or add additional context in comments.

3 Comments

revilotom Over a year ago

Thanks so much for your response! When trying to compile your code it complained about "Just" so I removed them both and then it seemed to work fine.

Li-yao Xia Over a year ago

Oh, that's right. I was looking for a total version of head but then I got distracted. I've just fixed it by using (!?), but dropping Just as you said also works.

revilotom Over a year ago

Thanks I didn’t know about the safe indexing operator!

Collectives™ on Stack Overflow

Parsing nested arrays in Aeson

1 Answer 1

3 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

3 Comments

Your Answer

Sign up or log in

Post as a guest

Related