Using JSON in Haskell to Serialize a Record

Question

I've been working on a very small program to grab details about Half Life 2 servers (using the protocol-srcds library). The workflow is pretty straightforward; it takes a list of servers from a file, queries each of them, and writes the output out to another file (which is read by a PHP script for display, as I'm tied to vBulletin). Would be nice if it was done in SQL or something, but seeing as I'm still just learning, that's a step too far for now!

Anyway, my question relates to serialization, namely, serializing to JSON. For now, I've written a scrappy helper function jsonify, such that:

jsonify (Just (SRCDS.GameServerInfo serverVersion
                           serverName   
                           serverMap    
                           serverMod    
                           serverModDesc
                           serverAppId  
                           serverPlayers
                           serverMaxPlayers 
                           serverBots
                           serverType
                           serverOS  
                           serverPassword
                           serverSecure  
                           serverGameVersioning)) = 
                            toJSObject [ ("serverName", serverName)
                                       , ("serverMap", serverMap)
                                       , ("serverPlayers", show serverPlayers)
                                       , ("serverMaxPlayers", show serverMaxPlayers) ]

(I'm using the Text.JSON package). This is obviously not ideal. At this stage, however, I don't understand using instances to define serializers for records, and my attempts to do so met a wall of frustration in the type system.

Could someone please walk me through the "correct" way of doing this? How would I go about defining an instance that serializes the record? What functions should I use in the instance (showJSON?).

Thanks in advance for any help.

hvr · Accepted Answer · 2011-07-24 08:07:50Z

6

You might want to consider using Data.Aeson instead which might be regarded as the successor to Text.JSON.

With aeson you define separate instances for serialize/deserializing (with Text.JSON you have to define both directions even if you need only one, otherwise the compile will annoy you -- unless you silence the warning somehow), and it provides a few operators making defining instances a bit more compact, e.g. the example from @hammar's answer can be written a little bit less noisy as shown below with the aeson API:

instance ToJSON SRCDS.GameServerInfo where
    toJSON (SRCDS.GameServerInfo {..}) = object
        [ "serverName"       .= serverName
        , "serverMap"        .= serverMap
        , "serverPlayers"    .= serverPlayers
        , "serverMaxPlayers" .= serverMaxPlayers
        ]

answered Jul 24, 2011 at 8:07

hvr

7,8453 gold badges36 silver badges47 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

frio Over a year ago

Thankyou for that. I've seen Data.Aeson mentioned, but Text.JSON still seemed to the be the canonical implementation. I'll try the Data.Aeson package tonight though; that does look remarkably clean :).

hvr Over a year ago

@frio, Text.JSON actually has been the "canonical implementation" for a long time... but now a shift is occurring to Data.Aeson...

hammar · Accepted Answer · 2011-07-24 00:36:04Z

1

One simple thing you can do is use record wildcards to cut down on the pattern code.

As for your type system problems, it's hard to give help without seeing error messages and what you've tried so far, however I suspect one thing that might be confusing is that the result of toJSObject will have to be wrapped in a JSObject data constructor as the return type of showJSON is supposed to be a JSValue. Similarly, the values of your object should also be of type JSValue. The easiest way to do this is to use their JSON instance and call showJSON to convert the values.

instance JSON SRCDS.GameServerInfo where
    showJSON (SRCDS.GameServerInfo {..}) =
        JSObject $ toJSObject [ ("serverName", showJSON serverName)
                              , ("serverMap", showJSON serverMap)
                              , ("serverPlayers", showJSON serverPlayers)
                              , ("serverMaxPlayers", showJSON serverMaxPlayers) ]

edited Jul 24, 2011 at 0:36

answered Jul 24, 2011 at 0:22

hammar

140k18 gold badges310 silver badges388 bronze badges

2 Comments

frio Over a year ago

Interesting, thanks for the pointer to record wildcards - would definitely help me cut back on the boilerplate! Will try your code shortly, but wrapping the toJSObject output in a JSObject looks like it'd solve one of the (many, fairly random) problems I was having. Is calling toJSObject in a showJSON instance a preferred/standard way of serializing records?

hammar Over a year ago

@frio: Any scheme for converting your type to a JSValue should be fine as long as your readJSON matches the format. toJSObject seems like a good fit for record types.

Collectives™ on Stack Overflow

Using JSON in Haskell to Serialize a Record

2 Answers 2

2 Comments

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related