Creating and accessing a substring in VB Script

Question

I am trying to create a simple string in VB script and then I would like to create an array with substrings from the original array. Then I may change the values as necessary. For example:

Full_string = "XYZABC"

Then, say I want an array comprising of two elements from Full_string:

'NA(0) = "XY"
NA(1) = "ZA"
NA(2) = "BC"'

Then if needed I want to change as follows:

NA(0)(0) = "D"

How can I do all these in VBScript?

VBScript can't index into a string to write to it. If REPLACE does'nt work for you, you will have to rebuild the string s=left(s,pos-1) & newstring & mid(s,pos+1) — Antoni Gual Via
– Antoni Gual Via, Commented Jul 27, 2022 at 10:14
@AntoniGualVia But it can generate an array from it see the answer below. — user692942
– user692942, Commented Jul 28, 2022 at 6:58

LesFerch · Accepted Answer · 2022-07-26 04:08:49Z

2

Create a two dimensional array based on the string size and the number of characters you want to break on (two in your example) and then iterate through the string to populate the array, like this:

FullString = "XYZABC"
BreakOn = 2

'Create a two dim array of correct size
ArraySize = Int(Len(FullString)/BreakOn)
ReDim aString(ArraySize,BreakOn)

'Populate array
j = 0
For i = 1 To Len(FullString) Step BreakOn
  For x = 0 To BreakOn - 1
    aString(j,x) = Mid(FullString,i+x,1)
  Next
  j = j + 1
Next

'Display array contents
For i = 0 To UBound(aString)
  WScript.Echo "---"
  For x = 0 To BreakOn - 1
    WScript.Echo aString(i,x)
  Next
Next

'Demonstrate change of array element
WScript.Echo aString(0,0)
aString(0,0) = "D"
WScript.Echo aString(0,0)

answered Jul 26, 2022 at 4:08

LesFerch

1,9972 gold badges8 silver badges28 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

user692942 Over a year ago

Nice approach, not sure the OP's question was clear enough and showed enough effort to warrant an answer, but great code example nonetheless.

Collectives™ on Stack Overflow

Creating and accessing a substring in VB Script

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related