how to convert string to object name. as3

Question

public class ColorLibrary {
    private var _allColorCodes:Object;

    public function ColorLibrary() {
        init();
    }

    private function init(){
        _allColorCodes = {
            'black'     :   '000000',
            'white'     :   'FFFFFF',
            'yellow'    :   '000000'
        }
    }

    public function exchangeColor(colors:String){
        var colorArray:Array = colors.split(',');
        for ( var i:int = 0; i < colorArray.length; i++ ) {
            _allColorCodes.getDefinitionByName(colorArray[i]);
        }

    }

}

any idea how to convert string to instance name? Thanks very much~! Strugglying here

What do you want to accomplish with your function (exchangeColor)? — Mattias
– Mattias, Commented Sep 19, 2011 at 7:30

Marty · Accepted Answer · 2011-09-19 07:41:24Z

2

You've already got an object there, so you can already go:

_allColorCodes.black .. etc

Considering that _allColorCodes is private, you can do a really nice little getter like so:

public function get colorCode():Object
{ 
    return _allColorCodes; 
}

And then just have:

trace(colorCode.black);
trace(colorCode.yellow);

All that said, what I would do is store all this stuff against constants in a class like ColorCodes, like this:

package
{
    public class ColorCodes
    {
        public static const BLACK:uint = 0x000000;
        public static const RED:uint = 0xFF0000;
        public static const BLUE:uint = 0x0000FF;
        public static const GREEN:uint = 0x00FF00;
        public static const WHITE:uint = 0xFFFFFF;
    }
}

And then access them via:

trace(
    ColorCodes.RED
);

Something slightly more advanced that you can do is make use of Proxy and flash_proxy to override the getProperty() method. This means you'll be able to go ColorLibrary.color straight off the bat:

package
{
    import flash.utils.Proxy;
    import flash.utils.flash_proxy;

    public class ColorLibrary
    {
        private var _allColorCodes:Object;

        public function ColorLibrary()
        {
            _allColorCodes = {
                'black'     :   '000000',
                'white'     :   'FFFFFF',
                'yellow'    :   '000000'
            }
        }

        override flash_proxy function getProperty(name:*)*
        {
            return _allColorCodes[name];
        }
    }
}

Response to comment:

Okay, you don't need to use getDefinitionByName here, you can simply use brackets to access a value of an object by parsing a string.

Example:

var object:Object = {
    something: 2,
    anotherThing: "something awesome"
};

trace(object["something"]); // same as object.something
trace(object["anotherThing"]); // same as object.anotherThing

Try something like this for your exchangeColor() function:

public function exchangeColor(colors:String):void
{
    var colorArray:Array = colors.split(',');

    for each(var i:String in colorArray)
    {
        trace(
            _allColorCodes[i]
        );
    }
}

edited Sep 19, 2011 at 7:41

answered Sep 19, 2011 at 7:27

Marty

39.5k19 gold badges97 silver badges164 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

user775735 Over a year ago

Thanks for the quick reply, but my situation is i have a string of colors var color:String = 'black, white, yellow'; and i use split to convert array then use this array to looks up the object and return the hex number. i want to do this _allColorCodes.colorArray[i], but this won't work. any ideas?

user775735 Over a year ago

Wow this is very fancy, first time see this. NICE i will give it a try. Thanks very much

Mattias · Accepted Answer · 2011-09-19 07:41:24Z

1

I can´t see why you would want to do it like this, but here is a function that passes a list of colors (String) and returns hex codes (Array). If one color does not exist you will get lost in the Array. I Recommend using ColorList.RED or at least ColorManager.getColor("red").

var colorList : Array = getColorList("black,yellow");

public function getColorList(colors : String) : Array
{
    var result : Array = new Array();
    var colorArray : Array = colors.split(',');

    for(var i : int = 0; i < colorArray.length ; i++)
    {
        if(_allColorCodes[colorArray[i]])
            result.push(_allColorCodes[colorArray[i]]);
    }

    return result;
}

answered Sep 19, 2011 at 7:41

Mattias

3,9074 gold badges31 silver badges50 bronze badges

1 Comment

user775735 Over a year ago

Wow Thanks very much, your solution is the one i am after, and it works perfectly. want to vote up your solution, but my reputation is not enought :( again thanks for the help!

Collectives™ on Stack Overflow

how to convert string to object name. as3

2 Answers 2

2 Comments

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

2 Comments

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related