4

I am trying to add the xmlns attribute to the resulting XML with a value passed by parameter during XSLT transformation using JDK Transformer (Oracle XML v2 Parser or JAXP) but it always defaults to http://www.w3.org/2000/xmlns/

My source XML

<test/>

My XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://example.com">
    <xsl:param name="myNameSpace" select="'http://neilghosh.com'"/>
    <xsl:template match="/">
        <process>
            <xsl:attribute name="xmlns:neil">
                <xsl:value-of select="$myNameSpace"/>
            </xsl:attribute>
        </process>
    </xsl:template>
</xsl:stylesheet>

My Result

<?xml version="1.0"?>
<process xmlns="http://www.w3.org/2000/xmlns/" xmlns:neil="neilghosh.com">
</process>

My Desired Result

<?xml version="1.0"?>
<process xmlns="http://example.com"  xmlns:neil="neilghosh.com">
</process>
Improve this question
1
  • You should use a valid URI for the namespace, e.g. http://example.com/, not http://example.com. Browsers will correct the latter to the former if you enter them into a location bar, but that's correcting an obvious mistake on input. You can't have an HTTP URI with no path part. Commented Aug 29, 2012 at 13:55

5 Answers 5

Reset to default
5

Firstly, in the XSLT data model, you don't want to create an attribute node, you want to create a namespace node.

Namespace nodes are usually created automatically: if you create an element or attribute in a particular namespace, the requisite namespace node (and hence, when serialized, the namespace declaration) are added automatically by the processor.

If you want to create a namespace node that isn't necessary (because it's not used in the name of any element or attribute) then in XSLT 2.0 you can use xsl:namespace. If you're stuck with XSLT 1.0 then there's a workaround, that involves creating an element in the relevant namespace and then copying its namespace node:

<xsl:variable name="ns">
  <xsl:element name="neil:dummy" namespace="{$param}"/>
</xsl:variable>
<process>
  <xsl:copy-of select="$ns/*/namespace::neil"/>
</process>
Improve this answer
Sign up to request clarification or add additional context in comments.

4 Comments

Does that work when the $ns variable holds a RTF rather than a node-set? I'd have expected to need an exslt:node-set() call or similar to convert it first.
Thanks the following code under template did not work <xsl:variable name="ns"> <xsl:element name="neil:dummy" namespace="{$myNameSpace}"/> </xsl:variable> <process> <xsl:copy-of select="$ns/*/namespace::neil"/> </process> Can you edit your solution to the exact XSLT I need to write for this question ?
@NeilGhosh, Maybe you have heard about the xxx:node-set() extension function?
Yes, I think it needs xx:node-set(). Sorry, I only point people in the right direction, I don't take them by the hand and walk them there - especially when it involves XSLT 1.0 because that's always such an unpleasant journey.
5

Michael Kay provided you with the correct answer, but based on your comments, you aren't sure how to use it in your transformation.

Here is a complete transformation:

 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pNamespace" select="'neilghosh.com'"/>

 <xsl:variable name="vDummy">
   <xsl:element name="neil:x" namespace="{$pNamespace}"/>
 </xsl:variable>

 <xsl:template match="/*">
  <xsl:element name="process" namespace="http://example.com">
    <xsl:copy-of select="namespace::*"/>
    <xsl:copy-of select="ext:node-set($vDummy)/*/namespace::*[.=$pNamespace]"/>
  </xsl:element>
 </xsl:template>
 </xsl:stylesheet>

When this transformation is applied on the provided XML document:

<test/>

the wanted, correct result is produced:

<process xmlns="http://example.com" xmlns:neil="neilghosh.com" />
Improve this answer

10 Comments

Thanks for the answer. I am getting the following error a.xsl<Line 11, Column 41>: XML-23049: (Error) FOTY0021: invalid node type
Is this because my JDeveloper's oracle.xml.parser.v2.XSLProcessor ? Any better way to v2 parser ?
Removed the Oracle v2 parser library and got above code running but output was <ns0:process xmlns:ns0="example.com" xmlns:neil="neilghosh.com"/>
@NeilGhosh, I have run this with all 9 XSLT processor I am working with -- all produce the output I copied and pasted into this answer. Can you use MSXML, .NET XslCompiledTransform, Saxon, XQSharp or AltovaXML (XML-SPY)?
I am not sure if I can use above parses in my code . I ran the same code in NetBeans and it gave ns0 prefix as well unnecessarily
|
2

Namespace declarations in XML are not attributes even though they look like attributes. In XSLT 2.0 you can use <xsl:namespace name="neil" select="$myNameSpace" /> to add a namespace declaration to the result tree dynamically but that feature is not available in XSLT 1.0.

Improve this answer

1 Comment

I added <xsl:element name="process" namespace="{$myNameSpace}"> <xsl:namespace name="neil" select="$myNameSpace" /> </xsl:element> under template but it still gives me output <process xmlns="neilghosh.com">
0

Don't try to create "xmlns" attributes yourself. Create the namespaces in the XSLT and they will be done automatically. This XSLT works (tested with Saxon 9.4):

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:neil="neilghosh.com"    
xpath-default-namespace="http://example.com"
xmlns="http://example.com" version="2.0">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:param name="myDynamicNamespace" select="'http://neilghosh.com'"/>

<xsl:template match="/">
    <xsl:element name="process">   
        <xsl:namespace name="neil" select="$myDynamicNamespace"/>
    </xsl:element>
</xsl:template>
</xsl:stylesheet>

And gives the following output:

<?xml version="1.0" encoding="UTF-8"?>
<process xmlns="http://example.com" xmlns:neil="http://neilghosh.com"/>
Improve this answer

6 Comments

The whole point of the question is that the value of xmlns is supposed to come from the parameter [sent by transformer.setParameter("myNameSpace", "example.com") ] "myNameSpace"
ok - so the element "process" should be in the namespace that comes from the parameter. I'll try to create an element inside of <process> that has the namespace from the parameter...
<xsl:template match="/"> <xsl:element name="process" namespace="{$myNameSpace}"> </xsl:element> </xsl:template>
I need to have it in the root tag that is process
xsl:namespace didn't work even tough <xsl:stylesheet version="2.0"
|
0

Finally got an workaround which worked with my XSLT Processor (Oracle XML V2 Parser)

I had to transform it to a DOM Document and then persist that DOM to filesystem instead of outputting directly to StreamResult

I used DOMResult in the transform method

Following XSLT fragment worked but there was an extra xmlns:xmlns="http://www.w3.org/2000/xmlns/" which was probably absorbed by Document and did not appear in the final output when I persisted to file system.

 <process>    
      <xsl:attribute name="xmlns">
        <xsl:value-of select="'http://example.com'"/>
      </xsl:attribute> 
 <process>

I know this is not the best way to do but given the parse constraint this is the only choice I have now.

Improve this answer

Comments

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.