swap! atom and then: java.lang.ClassCastException: java.lang.String cannot be cast to clojure.lang.IFn

Question

So, in my core.clj file I have:

(def page-buffer (BufferedReader. (InputStreamReader. (clojure.java.io/input-stream               (clojure.java.io/resource "mitochondria.html")))))    
(def parsed-page (atom ""))

and then later:

(defn -main [& args]
(let [port (Integer/parseInt (first args))]
(swap! parsed-page  (with-open []
                      (.toString (reduce #(.append %1 %2)
                                         (StringBuffer.) (line-seq page-buffer)))))
(println "Server is starting")
(println "port: " port)
(run-server port)))

This compiles and then I turn it into an uberjar. But when I run it I get the line with swap! blows up:

Exception in thread "main" java.lang.ClassCastException: java.lang.String cannot be cast to clojure.lang.IFn
at clojure.core$swap_BANG_.invoke(core.clj:2106)
at serve_pages_from_memory.core$_main.doInvoke(core.clj:29)
at clojure.lang.RestFn.applyTo(RestFn.java:137)
at serve_pages_from_memory.core.main(Unknown Source)

I tried this without using an atom and everything worked just fine (using a var defined with "def" to be a string) but eventually I want to send this var to multiple threads, so I need for this to be an atom or agent.

What have I done wrong?

UPDATE:

Jeremy Heiler, thanks. Fixed, but the result is ugly as sin:

(defn parse-buffer [& everything-else]
(with-open []
(.toString (reduce #(.append %1 %2)
                   (StringBuffer.) (line-seq page-buffer)))))

(defn -main [& args]
(let [port (Integer/parseInt (first args))]
(swap! parsed-page parse-buffer)
(println "Server is starting")
(println "port: " port)
(run-server port)))

I have to give an argument to parse-buffer or I get an error. But I do not use the argument, so this is ugly. I must be writing this wrong, yes?

Jeremy · Accepted Answer · 2012-08-31 15:39:58Z

You need to pass a function to swap!. Right now you are passing it a value.

(let [foo (atom 1)]
  (swap! foo + 2)
  @foo)

The above expression will return 3. The passed in function takes the current value of the atom, and the return value becomes the new value of the atom. Any extra arguments are passed to the given function.

To comment on your update: Yes, you do need to give an argument to the function used in swap!. The first argument is the current value of the the atom. However, you don't need to hack parse-buffer in order to make it work. You can just wrap it with an anonymous function.

Also, parse-buffer can be simplified greatly. Since line-seq returns a sequence of lines from the given reader, and str uses a StringBuilder internally, you can just apply it over the sequence.

(defn parse-buffer []
  (with-open [buf page-buffer]
    (apply str (line-seq buf))))

(defn -main [& args]
  (let [port (Integer/parseInt (first args))]
    (swap! parsed-page (fn [cur-val] (parse-buffer)))
    (println "Server is starting")
    (println "port: " port)
    (run-server port)))

Collectives™ on Stack Overflow

swap! atom and then: java.lang.ClassCastException: java.lang.String cannot be cast to clojure.lang.IFn

1 Answer 1

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Related