Foreach array and use array member in callback [duplicate]

Question

I have array of remote files address. I simply use for in to foreach array and in body of foreach, I starting HTTP GET request for data download. But everything is async and I need to know filename to save the file in request callback.

What is the best practice to solve this?

Demo code:

files = ["url.com/file.png", "url.com/file.doc"]

for file in files
  req = http.get file, (response) =>
    response.setEncoding 'binary'
    body = ""

    response.on "data", (chunk) =>
      body += chunk

    response.on "end", () =>
      #Here I needs to know the file name to save it
      fs.writeFileSync @currentFolder + "/Files/" + file, body, "binary"

Thank you!

What's the problem? Are you asking how to convert url.com/file.png to file.png? — Eric
– Eric, Commented Apr 24, 2013 at 7:52
No, on line with writeFileSync I needs to get value of original variable "file". But everything is async, so variable "file" will be filled only with last filename. — Martin
– Martin, Commented Apr 24, 2013 at 7:55
Are you sure? I thought coffeescript for loops used closures to prevent this kind of problem. — Eric
– Eric, Commented Apr 24, 2013 at 7:57

Deathspike · Accepted Answer · 2013-04-24 08:08:02Z

0

You have to scope it. Use a function like this:

files = ["url.com/file.png", "url.com/file.doc"]

for file in files
    ((file) ->
        req = http.get file, (response) =>
            response.setEncoding 'binary'
            body = ""

        response.on "data", (chunk) =>
            body += chunk

        response.on "end", () =>
            fs.writeFileSync @currentFolder + "/Files/" + file, body, "binary"
    ).call @, file

answered Apr 24, 2013 at 8:08

Deathspike

8,8206 gold badges49 silver badges83 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

mu is too short Over a year ago

Why not use do? See the bottom of this section: coffeescript.org/#loops

loganfsmyth · Accepted Answer · 2013-04-25 04:32:55Z

0

The proper way to do this in CoffeeScript is with a do call. Also setting the encoding to 'binary' makes no sense and just creates extra work to convert the data back and forth from a Buffer and a string.

for file in files
  do (file) =>
    req = http.get file, (response) =>
      parts = []

      response.on "data", (chunk) =>
        parts.push chunk

      response.on "end", () =>
        body = Buffer.concat parts
        fs.writeFileSync @currentFolder + "/Files/" + file, body

answered Apr 25, 2013 at 4:32

loganfsmyth

162k31 gold badges349 silver badges259 bronze badges

Collectives™ on Stack Overflow

Foreach array and use array member in callback [duplicate]

2 Answers 2

1 Comment

Comments

Linked

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Linked

Related