windows batch command for loop set environment variable

Question

I'm trying to find a way to dynamically build en environment variable that contains a list of JAR files under my app's WEB-INF/lib folder.

This is what I have so far, but it's over-writing itself each time, so when you reach the end of the loop, you just have the last file from the loop set in the variable.

 SETLOCAL ENABLEDELAYEDEXPANSION

for %%f IN (WEB-INF/lib/*.jar) DO (

  SET JAR_LIST=%JAR_LIST%;%%f

)

ECHO JAR_LIST -- %JAR_LIST%

So this produces...

C:\apache\Tomcat6.0\webapps\myapp>(SET JAR_LIST=.;xsltcbrazil.jar )

C:\apache\Tomcat6.0\webapps\myapp>(SET JAR_LIST=.;xsltcejb.jar )

C:\apache\Tomcat6.0\webapps\myapp>(SET JAR_LIST=.;xsltcservlet.jar )

C:\apache\Tomcat6.0\webapps\myapp>ECHO JAR_LIST -- .;xsltcservlet.jar

JAR_LIST -- .;xsltcservlet.jar

RGuggisberg · Accepted Answer · 2013-07-11 16:48:10Z

5

Change

SET JAR_LIST=%JAR_LIST%;%%f

to

SET JAR_LIST=!JAR_LIST!;%%f

This will use the run-time value instead of the load-time value. It might be better to do this to avoid the leading ;

SETLOCAL ENABLEDELAYEDEXPANSION
SET "JAR_LIST="
for %%f IN (WEB-INF/lib/*.jar) DO (
if "!JAR_LIST!"=="" (SET JAR_LIST=%%f) ELSE (SET JAR_LIST=!JAR_LIST!;%%f)
)
ECHO JAR_LIST -- %JAR_LIST%

edited Jul 11, 2013 at 16:48

answered Jul 11, 2013 at 16:40

RGuggisberg

4,7802 gold badges21 silver badges29 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

ajb Over a year ago

See also stackoverflow.com/questions/22774259/…. If you want to use the variable later, you need ENDLOCAL & SET JAR_LIST=%JAR_LIST%.

Collectives™ on Stack Overflow

windows batch command for loop set environment variable

1 Answer 1

1 Comment

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Linked

Related