I have an array that is like
my @array = ('cookies','balls','cookies','balls','balls');
but the real one is much bigger/longer.
How do I output the count of each repeated string in the array?
like in the example, cookies is 2 and balls is 3.
Add a comment
|
4 Answers
I think we can use
map {$count{$_}++;} @array;
instead of
foreach(@array)
{
unless(defined($count{$_}))
{
$count{$_} = 1;
}
else {
$count{$_}++;
}
}
to simplify the code.
2 Comments
Dave Cross
Using
map in a void context is a bad idea. I'd write that as $count{$_}++ foreach @array.
TLP
You don't have to check if a key is defined before you use the increment operator on it, it will automatically inc undef to 1, without warning. You can just do
$count{$_}++ for @array."How do I output the count of each repeated string in the array?"
#!/usr/bin/perl
use strict;
use warnings;
my @array = ('cookies','balls','cookies','balls','balls', 'orphan');
my %count;
$count{$_}++ foreach @array;
#removing the lonely strings
while (my ($key, $value) = each(%count)) {
if ($value == 1) {
delete($count{$key});
}
}
#output the counts
while (my ($key, $value) = each(%count)) {
print "$key:$value\n";
}
Prints:
cookies:2
balls:3
Mind, that 'orphan' wasn't output.
12 Comments
user2285115
is there a way to print in the format
cookies:2 /n balls:3?
user4035
@user2285115 sure, will do it now
user2285115
what do you mean by 'orphan'?
user4035
@user2285115 "what do you mean by 'orphan'?" - you said, that only repeated strings should be counted. So I decided to create a non-repeated string in array to make sure, that the algorithm works correctly.
Dave Cross
"Do you know, why Perl doesn't generate a warning, when you refer to an undefined hash element" - yes, it's called 'autovivification' and it's one of Perl's best features.
|
Using Perl that's a little more idiomatic than some of the other answers...
use strict;
use warnings;
use 5.010;
my @array = ('cookies','balls','cookies','balls','balls');
my %count;
$count{$_}++ foreach @array;
say "$_: $count{$_}" foreach grep { $count{$_} != 1 } keys %count;
Comments
Try this more shorter code u will not get any thing shorter than this
my @array = ('cookies','balls','cookies','balls','balls');
my $hashh = {};
foreach (@array){
if(exists $hashh->{$_}){
$hashh->{$_}++;
} else{
$hashh->{$_} = 1;
}
}
print Dumper($hashh);
2 Comments
RobEarl
Removing the
if ... else would be shorter. If $hashh->{$_} doesn't exist, it'll automatically be created when you increment it. $hashh->{$_}++ for @array;Dave Cross
I think that
$hashh->{$_}++ for @array is quite a lot shorter than your foreach loop :-)