Join Array of strings except empty

Question

I try to find an easy way to concatenate strings from an array - but only if they are not empty.

Example:

Dim strArr(3)
strArr(0) = "This"
strArr(1) = "is"
strArr(2) = ""
strArr(3) = "a"
strArr(4) = "test"

strResult = Join(strArr, "***")
MsgBox strResult

will result in this text: This***is******a***test

but it should be: This***is***a***test

So the empty string should be ignored.

MC ND · Accepted Answer · 2015-04-27 21:43:50Z

4

Option Explicit

Dim aStrArray
    aStrArray = Array("", "", "This", "", "", "is", "", "", "", "a", "test", "", "")

Dim strResult    
    strResult = MyJoin(aStrArray, "***")
    WScript.Echo strResult


Function MyJoin( inputArray, inputDelimiter )
Dim delimiter
    delimiter = Chr(1) & Chr(2) 
    With New RegExp
        .Pattern =  "^(?:" & delimiter & ")+" & _ 
                    "|(?:" & delimiter & ")+$" & _ 
                    "|(?:" & delimiter & ")+(" & delimiter & ")"
        .Global = True 
        MyJoin = Replace(.Replace(Join(inputArray, delimiter), "$1"), delimiter, inputDelimiter)
    End With
End Function

You can replace multiple occurrences of the delimiter with only one.

In the function in sample code:

A delimiter is defined to be used to join all the elements in the input array. It is created to reduce the probability of finding it inside the data.
A regular expression is created to handle initial, end and repeated occurences of the delimiter.
The input array is joined using the generated delimiter
The regular expression is used to remove non desired delimiter sequences
The generated delimiter is replaced by the input delimiter

edited Apr 27, 2015 at 21:43

answered Apr 27, 2015 at 14:48

MC ND

71.1k8 gold badges95 silver badges136 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Klaus F. Over a year ago

Seems that there is no built-in-way to handle this. Will use that function since it avoids problems if the delimiter is part of the text.

JosefZ · Accepted Answer · 2015-04-27 14:38:08Z

1

Next code snippet could help (and even ReDims the strArr):

option explicit
Dim strArr, strResult, strJoinString
ReDim strArr(4)
strArr(0) = "This"
strArr(1) = "is"
strArr(2) = ""
strArr(3) = "a"
strArr(4) = "test"

strJoinString = "€€€"
strResult = Join(strArr, strJoinString)
Do While Instr(1, strResult, strJoinString & strJoinString, vbBinaryCompare) > 0
  strResult = Replace( strResult, strJoinString & strJoinString, strJoinString)
Loop
strArr = Split(strResult, strJoinString)
strResult = Join(strArr, "***")

MsgBox strResult & vbNewLine & Join(strArr, "-")

Make sure strJoinString does not match any array element!

answered Apr 27, 2015 at 14:38

JosefZ

30.5k6 gold badges52 silver badges96 bronze badges

Comments

Ansgar Wiechers · Accepted Answer · 2015-04-27 15:06:24Z

0

One way is to copy all non-empty fields to a dictionary, then join the values of that dictionary:

Set d = CreateObject("Scripting.Dictionary")

For i = 0 To UBound(strArr)
  If strArr(i) <> "" Then d.Add i, strArr(i)
Next

WScript.Echo Join(d.Items, "***")

answered Apr 27, 2015 at 15:06

Ansgar Wiechers

202k27 gold badges286 silver badges363 bronze badges

Collectives™ on Stack Overflow

Join Array of strings except empty

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related