Batch File: Explode User Entered String Into An Array

Question

I am writing a simple batch file that copies a video from a web server using a user submitted url. I would like to extract parts of the user submitted string and set them as a variables. Below is my example code.

@echo OFF
SET outputdir= %~dp0output\
SET libav= %~dp0libav\win64\usr\bin
CD %libav%
SET /p code= "Paste the download code from your browser: "

The user will be inputting a string that is in this exact format for %code%:

avconv -i "http://example.com/i/index_0_av.m3u8" -codec copy -qscale 0 video_name.mp4

I want to use a space as the delimiter. I need to set the 3rd item as %url% and 8th item as %filename%. Basically I am trying to do what explode() does in PHP.

The goal is to run the following as the final line in the file.

call avconv -i "%url%" -codec copy -qscale 0 %outputdir%%filename%

Btw. Apple-HLS streams are transport streams avconv -i "http://example.com/i/index_0_av.m3u8" -c copy -qscale 0 "video_name.ts" — Endoro
– Endoro, Commented May 6, 2015 at 7:28

Aacini · Accepted Answer · 2015-05-06 06:51:54Z

2

Although there are several ways to do what you want in Batch, the version below do it emulating PHP's explode:

@echo off
setlocal EnableDelayedExpansion

set code=avconv -i "http://example.com/i/index_0_av.m3u8" -codec copy -qscale 0 video_name.mp4

rem Explode "code" string into "item" array
set i=0
for %%a in (%code%) do (
   set /A i+=1
   set "item[!i!]=%%~a"
)

rem Set 3rd item as url and 8th item as filename
set url=%item[3]%
set filename=%item[8]%

echo call avconv -i "%url%" -codec copy -qscale 0 %outputdir%%filename%

answered May 6, 2015 at 6:51

Aacini

67.7k12 gold badges74 silver badges114 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Trigger · Accepted Answer · 2015-05-06 06:08:54Z

0

For /f "tokens=3" %A in ("%CODE%") Do Echo %A

Which is same as

For /f "tokens=3" %A in ("avconv -i http://example.com/i/index_0_av.m3u8 -codec copy -qscale 0 video_name.mp4") Do Echo %A

I removed your quotes. Quotes only needed with spaces. URLs can't have spaces.

In a batch file use %%A ratherthan %A at command prompt.

If you need quotes see UseBackQ option where single quotes enclose string.

answered May 6, 2015 at 6:08

Trigger

1453 bronze badges

Comments

Stephan · Accepted Answer · 2015-05-06 06:27:47Z

0

:loop
SET /p "code=Paste the download code from your browser: "
for /f "tokens=3,8,9 delims= " %%a in ("%code%") do (
  if "%%b"=="" echo too few parameters & goto :loop
  if not "%%c"=="" echo too much parameters & goto :loop
  set "url=%%~a"
  set "filename=%%b"
)
echo %url%, %filename%

Note: the tilde in %%~a removes the quotes. Leave out the tilde, if you want to keep the quotes.

Edited to implement a simple input check

edited May 6, 2015 at 6:27

answered May 6, 2015 at 6:13

Stephan

56.7k11 gold badges66 silver badges97 bronze badges

Collectives™ on Stack Overflow

Batch File: Explode User Entered String Into An Array

3 Answers 3

Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related