How to plot histograms from rows in data file gnuplot

Question

t.dat file looks like this:

The objective is to print 4 series of histograms, each one separated with spaces, one for each group of every 40 lines. So that histogram group 1 plots data from lines 1:40, second group plots the data from lines 41:80, and so on. So far I've managed to print the first group of histograms separately:

set boxwidth 0.9 relative
set style data histograms
set style fill solid 1.0 border -1
set xtics ("1" 20, "4" 60, "8" 100, "16" 140)
plot 't.dat' using 1 with boxes ls 6 axes x1y1

and print the four groups concatenated:

plot 't.dat' using 1 every ::0::39 with boxes ls 6 axes x1y1

How do I do to plot the other groups in the same plot?

I rolled back the question to its original version because you posted the update as new question. This keeps this question here much clearer. — Christoph
– Christoph, Commented Jun 24, 2015 at 20:19

Christoph · Accepted Answer · 2015-05-25 18:05:35Z

Note, that set style data histograms is ignored, because you overwrite it with the with boxes, and boxes and histograms are different ways to plot bar charts from the view point of grouping and arranging the data.

If you can plot the first group with

plot "t.dat" using 0:1 every ::0::39 with boxes

then you can plot the second group with

plot "t.dat" using 0:1 every ::40::79 with boxes

(using 1, like you used is implicitely converted to using 0:1 by gnuplot). These two plots would overlap because the zeroth column, i.e. the number of the current row only counts the rows which are available after applying the every filter, so in both cases the x-values go from 0 to 39. To have both plotted beneath each other you must add 40 to the second plot (or maybe 41 to have a small gap between the two:

plot "t.dat" using 0:1 every ::0::39 with boxes,\
     "" using ($0 + 41):1 every ::40::79 with boxes

Now, to plot all four groups you can either expand this plot command to hold also the other two groups, or you iterate over them with

set boxwidth 0.7 relative
set style fill solid 1.0 noborder
set xtics ("1" 19.5, "4" 60.5, "8" 101.5, "16" 142.5)
unset key 
plot for [i=1:4] 't.dat' using ($0+(i-1)*41):1 every ::((i-1)*40)::(i*40-1) with boxes lt i

enter image description here

Collectives™ on Stack Overflow

How to plot histograms from rows in data file gnuplot

1 Answer 1

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related