creating a rank list by sorting an array

Question

I have two arrays where one array represents a collection of names and the other describes their associated marks.I wanted to sort the marks inside the array in ascending order, and then also the respective names related to the marks.

My aim is to create a rank list. I am using Processing to do this

float sum = 0;

String [] name = {"A", "B", "C", "D","E"};
float [] mark = {12, 2, 4, 6, 23};

void setup() {

  size(600, 600);
  smooth();
}

void draw() {
  background(225);
  fill(0);
  println(name.length); 
  for (int i =0; i<name.length; i++) {
    text(name[i] + ":"+ mark[i], 100, 100+i*50);
  }
}

/////// i wanted to sort it as E:23,    A:12,    D:6,     C:4,     B:2

It would be great if someone can help me with this. :)

Many thanks in advance, Yousuf

Could you specify the language in your tags please? Looks like C, but want to be sure... Also, the various functions you are using look to be from a library - perhaps the Processing library? — Michael Dorgan
– Michael Dorgan, Commented Oct 15, 2015 at 23:19
Hi @MichaelDorgan I am using processing which is based on Java — yousufali.n
– yousufali.n, Commented Oct 15, 2015 at 23:27
Why are you using two arrays? Maps would be a much better choice — sam
– sam, Commented Oct 16, 2015 at 0:47

v.k. · Accepted Answer · 2017-07-10 10:11:53Z

1

You can make a data holder class implementing Comparable. I think you could also use a Map, like a hashMap.

Here a data holder class example:

import java.util.Collections;

ArrayList <Data> d = new ArrayList<Data>();

void setup() {
  size(600, 600);

  d.add(new Data("A", 12));
  d.add(new Data("B", 2));
  d.add(new Data("C", 4));
  d.add(new Data("D", 6));
  d.add(new Data("E", 23));



  println("before sorting:\n" + d);

  //used reverseOrder as it goes decrescent, but you could just reverse
  //the "natural" order in the class it self. Exchange -1 and 1 in compareTo()
  // and use Collections.sort(d); here
  Collections.sort(d, Collections.reverseOrder());

  println("after sorting:\n" + d);
}


/////// i wanted to sort it as E:23,    A:12,    D:6,     C:4,     B:2


class Data implements Comparable {
  String name;
  int mark;

  Data(String _n, int _m) {
    name = _n;
    mark = _m;
  }

  // this sets the 'natural' order of Data
  @Override
    int compareTo(Object o) {
    Data other = (Data) o;

    if (other.mark > mark) {
      return -1;
    } else if (other.mark < mark) {
      return 1;
    }
    return 0;
  }


  // this to get a nice looking output in console...
  @Override
    String toString() {
    return name + ":" + nf(mark, 2);
  }
}

edited Jul 10, 2017 at 10:11

answered Oct 16, 2015 at 0:08

v.k.

2,8642 gold badges23 silver badges29 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

yousufali.n Over a year ago

Thanks a lot @v.k. the code works well. I now have to start learn about the maps :)

v.k. Over a year ago

There is also intDict which you can try

Collectives™ on Stack Overflow

creating a rank list by sorting an array

1 Answer 1

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related