"continue" equivalent command in nested loop in Windows Batch

Question

I have a batch file which contains nested loop with continue-like command:

for %%i in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
    for %%j in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
        if %%i gtr %%j goto CONTINUE
        test.exe 0 %%i %%j 100000 > "%%i_%%j".txt
        :CONTINUE
        rem
    )
)

But when if statement is true for the first time, it does not iterate further. I only get text files upto 1_256.txt. So it seems that goto CONTINUE has a problem. What is wrong with my batch file?

In short, labels (like :CONTINUE) cannot be used inside a loop. — lit
– lit, Commented Apr 1, 2016 at 17:58

Community · Accepted Answer · 2017-05-23 12:10:03Z

23

goto :Label inside of a block of code () like a for loop breaks the block context, so everything after the :Label is treated as being outside of the block. So you need to invert the if condition to not need goto as ths's answer demonstrates, or you place the code fragment with goto and :Label into a subroutine and use call like this:

for %%i in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
    for %%j in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
        call :SUB %%i %%j
    )
)
exit /B

:SUB outer inner
if %1 gtr %2 goto CONTINUE
test.exe 0 %1 %2 100000 > "%1_%2.txt"
:CONTINUE
rem
exit /B

edited May 23, 2017 at 12:10

CommunityBot

11 silver badge

answered Apr 1, 2016 at 13:40

aschipfl

35.3k12 gold badges62 silver badges106 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

ths · Accepted Answer · 2016-04-01 13:45:39Z

7

it seems what you are actually trying to accomplish is a poor man's "less or equal than".
In this case, why not use the real "less or equal than", which is LEQ?
Additionally, you seem to want the output of test.exe in the "%%i_%%j".txt file, so don't use echo.

So this would be

for %%i in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
    for %%j in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
        if %%i LEQ %%j test.exe 0 %%i %%j 100000 > "%%i_%%j".txt
    )
)

edited Apr 1, 2016 at 13:45

answered Apr 1, 2016 at 12:41

ths

2,9521 gold badge19 silver badges23 bronze badges

1 Comment

arnobpl Over a year ago

Thanks. That solves my purpose without using any continue-like command. However, I assume, there is no "good" (user-friendly) continue equivalent thing in Windows batch scripting. I think, to accomplish such thing in complex scenario, some "dirty coding trick" is needed.

Maverick · Accepted Answer · 2024-06-30 16:44:36Z

1

A user-friendly option is to add an IF "ISCONTINUE" layer:

SETLOCAL ENABLEDELAYEDEXPANSION

for %%i in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (
    for %%j in (1, 2, 4, 8, 16, 32, 64, 128, 256) do (

                SET ISCONTINUE=
                if %%i gtr %%j SET ISCONTINUE=1
                SET !ISCONTINUE! NEQ "1" (


                test.exe 0 %%i %%j 100000 > "%%i_%%j".txt


                )

    )
)

answered Jun 30, 2024 at 16:44

Maverick

111 bronze badge

Collectives™ on Stack Overflow

"continue" equivalent command in nested loop in Windows Batch

3 Answers 3

Comments

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related