Split a string directly into array

Question

Suppose I want to pass a string to awk so that once I split it (on a pattern) the substrings become the indexes (not the values) of an associative array.

Like so:

$ awk -v s="A:B:F:G" 'BEGIN{ # easy, but can these steps be combined?
                            split(s,temp,":")  # temp[1]="A",temp[2]="B"...
                            for (e in temp) arr[temp[e]] #arr["A"], arr["B"]...
                            for (e in arr) print e 
                            }'
A
B
F
G

Is there a awkism or gawkism that would allow the string s to be directly split into its components with those components becoming the index entries in arr?

The reason is (bigger picture) is I want something like this (pseudo awk):

awk -v s="1,4,55" 'BEGIN{[arr to arr["1"],arr["5"],arr["55"]} $3 in arr {action}'

Ed Morton · Accepted Answer · 2017-02-09 23:48:10Z

5

No, there is no better way to map separated substrings to array indices than:

split(str,tmp); for (i in tmp) arr[tmp[i]]

FWIW if you don't like that approach for doing what your final pseudo-code does:

awk -v s="1,4,55" 'BEGIN{split(s,tmp,/,/); for (i in tmp) arr[tmp[i]]} $3 in arr{action}'

then another way to get the same behavior is

awk -v s=",1,4,55," 'index(s,","$3","){action}'

edited Feb 9, 2017 at 23:48

answered Feb 9, 2017 at 22:00

Ed Morton

209k18 gold badges90 silver badges212 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

dawg Over a year ago

I think that split(str,tmp); for (i in tmp) arr[tmp[i]] is probably the way to go. Thanks!

NeronLeVelu Over a year ago

to avoid missing surroundig separator of s in second solution I propose this awk -v s="A:B:C:G" 's ~ "(^|:)" $3 "(:|$)"{action}'

Ed Morton Over a year ago

@NeronLeVelu That turns it into a regexp comparison so then you need to worry about regexp metacharacters in the strings. The original code used a string comparison ($3 in arr) and so does the code I posted using index() so regexp metacharacters will just be treated literally.

NeronLeVelu Over a year ago

ok, i forget to assume that part, you are pointing right about this possible issue

James Brown · Accepted Answer · 2017-02-09 21:51:02Z

2

Probably useless and unnecessarily complex but I'll open the game with while, match and substr:

$ awk -v s="A:B:F:G" '
BEGIN {
    while(match(s,/[^:]+/)) {
        a[substr(s,RSTART,RLENGTH)]
        s=substr(s,RSTART+RLENGTH)
    }
    for(i in a)
        print i
}'
A
B
F
G

I'm eager to see (if there are) some useful solutions. I tried playing around with asorts and such.

answered Feb 9, 2017 at 21:51

James Brown

37.7k8 gold badges52 silver badges64 bronze badges

Comments

Jose Ricardo Bustos M. · Accepted Answer · 2017-02-09 22:09:36Z

2

Other way kind awkism

cat file

1 hi
2 hello
3 bonjour
4 hola
5 konichiwa

Run it,

awk 'NR==FNR{d[$1]; next}$1 in d' RS="," <(echo "1,2,4") RS="\n" file

you get,

1 hi
2 hello
4 hola

answered Feb 9, 2017 at 22:09

Jose Ricardo Bustos M.

8,1847 gold badges44 silver badges66 bronze badges

Collectives™ on Stack Overflow

Split a string directly into array

3 Answers 3

4 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

4 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related