Create JSON strings from Groovy variables in Jenkins Pipeline

Question

I have to create this JSON file in Groovy. I have try many things (JsonOutput.toJson() / JsonSlurper.parseText()) unsuccessfully.

{
   "attachments":[
      {
         "fallback":"New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
         "pretext":"New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
         "color":"#D00000",
         "fields":[
            {
               "title":"Notes",
               "value":"This is much easier than I thought it would be.",
               "short":false
            }
         ]
      }
   ]
}

This is for posting a Jenkins build message to Slack.

in title of question you asking about parsing, and in question itself you asking about creating json file. could you please clarify what you want/try to do. — daggett
– daggett, Commented Jun 23, 2017 at 10:12
@daggett i would like to create those JSON object into a groovy variable. — Mr_DeLeTeD
– Mr_DeLeTeD, Commented Jun 23, 2017 at 14:38

hisener · Accepted Answer · 2017-12-14 17:16:55Z

79

JSON is a format that uses human-readable text to transmit data objects consisting of attribute–value pairs and array data types. So, in general json is a formatted text.

In groovy json object is just a sequence of maps/arrays.

parsing json using JsonSlurperClassic

//use JsonSlurperClassic because it produces HashMap that could be serialized by pipeline
import groovy.json.JsonSlurperClassic

node{
    def json = readFile(file:'message2.json')
    def data = new JsonSlurperClassic().parseText(json)
    echo "color: ${data.attachments[0].color}"
}

parsing json using pipeline

node{
    def data = readJSON file:'message2.json'
    echo "color: ${data.attachments[0].color}"
}

building json from code and write it to file

import groovy.json.JsonOutput
node{
    //to create json declare a sequence of maps/arrays in groovy
    //here is the data according to your sample
    def data = [
        attachments:[
            [
                fallback: "New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
                pretext : "New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>",
                color   : "#D00000",
                fields  :[
                    [
                        title: "Notes",
                        value: "This is much easier than I thought it would be.",
                        short: false
                    ]
                ]
            ]
        ]
    ]
    //two alternatives to write

    //native pipeline step:
    writeJSON(file: 'message1.json', json: data)

    //but if writeJSON not supported by your version:
    //convert maps/arrays to json formatted string
    def json = JsonOutput.toJson(data)
    //if you need pretty print (multiline) json
    json = JsonOutput.prettyPrint(json)

    //put string into the file:
    writeFile(file:'message2.json', text: json)

}

edited Dec 14, 2017 at 17:16

hisener

1,5311 gold badge18 silver badges27 bronze badges

answered Jun 23, 2017 at 10:10

daggett

29k3 gold badges52 silver badges61 bronze badges

Sign up to request clarification or add additional context in comments.

6 Comments

Chris F Over a year ago

I'm trying to do this. I get "ERROR: org.jenkinsci.plugins.scriptsecurity.sandbox.RejectedAccessException: Scripts not permitted to use new groovy.json.JsonSlurperClassic" What am I missing?

daggett Over a year ago

stackoverflow.com/questions/38276341/…

David Over a year ago

This doesn't work for me in the latest version of jenkins (2.138.3). I get an issue on the writeJSON step:

WriteJSONStep(file: String, json: JSON{}, pretty?: int): java.lang.UnsupportedOperationException: must specify $class with an implementation of interface net.sf.json.JSON

More context here: stackoverflow.com/questions/53337109/…

daggett Over a year ago

@DavidGoate, in this case don't use writeFile, but the last three commands in code: JsonOutput.toJson, JsonOutput.prettyPrint, writeFile.

Alexander Samoylov Over a year ago

Thank you for the information about JsonSlurperClassic. I tried JsonSlurper, but it causes NotSerializableException if "new" is called more than once, even despite NonCPS annotation.

|

mrfred · Accepted Answer · 2018-02-13 23:59:38Z

23

Found this question while I was trying to do something (I believed) should be simple to do, but wasn't addressed by the other answer. If you already have the JSON loaded as a string inside a variable, how do you convert it to a native object? Obviously you could do new JsonSlurperClassic().parseText(json) as the other answer suggests, but there is a native way in Jenkins to do this:

node () {
  def myJson = '{"version":"1.0.0"}';
  def myObject = readJSON text: myJson;
  echo myObject.version;
}

Hope this helps someone.

Edit: As explained in the comments "native" isn't quite accurate.

edited Feb 13, 2018 at 23:59

answered Dec 1, 2017 at 19:47

mrfred

6315 silver badges15 bronze badges

4 Comments

Nigel Kirby Over a year ago

Good call, though this is not quite native, it requires the pipeline utility steps plugin. An excellent plugin to make use of. Full docs here

sirineBEJI Over a year ago

if we have a string '[ {"version":"1.0.0"} , {"version":"2.0.0"}]' how to read the array ?

Anand Rockzz Over a year ago

You will need Pipeline Utility Steps plugin as mentioned here

333kenshin Over a year ago

this addresses the opposite of the OPs question: how to go from object to json string

Azat · Accepted Answer · 2019-12-31 19:44:12Z

2

If you are stucked on an installation using sandboxes and Jenkins Script Security plugin with no possibility to add whitelisted classes/methods, the only way I found is the following :

def slackSendOnRestrictedContext(params) {

    if (params.attachments != null) {
        /* Soooo ugly but no other choice with restrictions of
           Jenkins Script Pipeline Security plugin ^^ */
        def paramsAsJson = JsonOutput.toJson(params)
        def paramsAsJsonFromReadJson = readJSON text: paramsAsJson
        params.attachments = paramsAsJsonFromReadJson.attachments.toString()
    }

    slackSend (params)
}

edited Dec 31, 2019 at 19:44

Azat

2,3351 gold badge28 silver badges33 bronze badges

answered Apr 9, 2019 at 15:57

Nicolas Vuillamy

71010 silver badges17 bronze badges

1 Comment

Marslo Over a year ago

JsonOutput.toJson( map ) works to me

Nikola Reljin · Accepted Answer · 2019-01-09 18:01:54Z

-1

This will return value of the "version" from the jsonFile file:

def getVersion(jsonFile){

  def fileContent = readFile "${jsonFile}"
  Map jsonContent = (Map) new JsonSlurper().parseText(fileContent)
  version = jsonContent.get("version")

  return version

}

answered Jan 9, 2019 at 18:01

Nikola Reljin

11 bronze badge

Collectives™ on Stack Overflow

Create JSON strings from Groovy variables in Jenkins Pipeline

4 Answers 4

6 Comments

4 Comments

1 Comment

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

4 Answers 4

6 Comments

4 Comments

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related