Use a for loop variable to call a predefined variable

Question

I'm looking to use a variable which gets defined inside a for loop and use it to call a predefined variable.

For example: To start the program "Slack" I need to call the variable %Slack%. The batch file will take your input, so If I input "Slack", the variable !filename[%%i]! will be assigned "Slack". Once that is done, I wish to call %Slack% using !filename[%%i]!. As per logic: %!filename[%%i]!%

Using %!filename[%%i]!% will make the batch file crash and close.

Setting set file=!filename[%%i]! and running it with %file% will return nothing.

Any smart trick?

@echo off

setlocal EnableDelayedExpansion

:: Predefined variables
for /f "delims== tokens=1,2" %%G in (D:\programs.txt) do set %%G=%%H

set /P "filenames=Enter programs to install: "

:: Puts input into array
set n=0
for %%a in (%filenames%) do (
    set /A n+=1
    set "filename[!n!]=%%~a"
)

:: Run variables imported from programs.txt
for /L %%i in (1,1,%n%) do (

    :: This is where I want !filename[%%i]! to be called as %!filename[%%i]!%

)

pause
endlocal

program.txt example

Slack=C:\Users\username\AppData\Local\slack\slack.exe
Text=C:\textfile.txt
Program=C:\program.bat & C:\program_license.txt

It would be helpful if, in your question body, you also included, (formatted as code), an example of the content of D:\programs.txt. — Compo
– Compo, Commented Mar 13, 2019 at 12:49
Nothing "crashes"; open a command prompt window and run the batch file from there by typing its path/name; then you can see any error messages; also temporarily remove @echo off and check all the command echoes. Anyway, %!variable!% makes no sense unless you have got a variable that is called !variable! (including the !, which is not the case here); why is !variable! not good enough for you? — aschipfl
– aschipfl, Commented Mar 13, 2019 at 13:09
@aschipfl because !variable! only returns Slack. With this string return I want to somehow use it to call a %Slack% variable (Defined from programs.txt at line 6). — trezx
– trezx, Commented Mar 13, 2019 at 13:21
CALL echo %%!filename[%%i]!%% or CALL START "" %%!filename[%%i]!%% — Squashman
– Squashman, Commented Mar 13, 2019 at 13:28
Based upon your provided example, your initial For loop could look like this: For /F "UseBackDelims=" %%A In ("D:\programs.txt")Do Set "%%A" — Compo
– Compo, Commented Mar 13, 2019 at 16:51

dbenham · Accepted Answer · 2019-03-14 06:55:19Z

3

I don't like to use the CALL hack described in the comments because 1), it is relatively slow, and 2) it causes an extra round of parsing that can require additional escaping (not an issue here). Even worse, it will corrupt quoted ^ - "^" becomes "^^", and there is no escape sequence that can prevent that.

My solution is to add an additional FOR loop so that the expansion can be staged.

for /L %%i in (1,1,%n%) do for %%A in ("!filename[%%i]!") do echo !%%~A!

This is certainly more verbose than the CALL hack, but it is a good code pattern to learn because it is more universally applicable.

edited Mar 14, 2019 at 6:55

answered Mar 14, 2019 at 6:23

dbenham

132k29 gold badges273 silver badges410 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

trezx Over a year ago

Works fine as well. Replaced it with this. Thank you

Collectives™ on Stack Overflow

Use a for loop variable to call a predefined variable

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related