Merge fields from multiple nested arrays in JSON input into new payload array using Dataweave

Question

I am using Anypoint Studio 7.3 and Mule 4.2.

Using the JSON input below, I would like to create new payloads to write to database tables including a payload which builds a list of customers from each record entry in the array to create a list entry looking like this:

[{
    recordId,
    customerId
}]

and the same for a list of transactions with each list entry looking like this:

[{
     recordId
     customerId
     transactionId
}]

but when I try to transform the data the field values show either as null or as a list instead of a single field in the object like this:

{
    "customers": [{
        "record": "1234",  
        "customerId": [
            "5435e1cd-146d-4aac-9164-4a2d80d5eccd"
        ]
    }]
}

instead of this:

{
    "customers": [{
        "recordId": "1234",
        "customerId": "5435e1cd-146d-4aac-9164-4a2d80d5eccd"
    }]
}

JSON INPUT:

{
    "records": [{
        "recordId": "1234",
        "customers": [{
            "customerId": "1234",
            "transactions": [{
                "transactionId": "1234",
                "prices": [{
                    "priceId": "1234",
                    "price": 1.00
                }]
            }]
        }]
    }]
}

Thanks for any help

machaval · Accepted Answer · 2019-10-09 14:19:55Z

3

In order to return the list of customers from each record

%dw 2.0
output application/java
---
payload.records flatMap 
    ((record, index) -> 
        record.customers map ((customer, index) -> 
            {
              recordId: record.recordId,
              customerId: customer.customerId          
            }
        )
    )

And for returning list of transactions with each list entry

%dw 2.0
output application/json
---
payload.records flatMap 
    ((record, index) -> 
        record.customers flatMap ((customer, index) -> 
            customer.transactions map ((transaction, index) -> 
                {
                    recordId: record.recordId,
                    customerId: customer.customerId,
                    transactionId: transaction.transactionId        
                }
            )
        )
    )

The key part here is using flatMap for flattening nesting levels of arrays into one.

answered Oct 9, 2019 at 14:19

machaval

5,06916 silver badges20 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

user3165854 Over a year ago

Thanks I hadn't seen the flatMap, I had been looking at flatten. Thanks for your help.

Collectives™ on Stack Overflow

Merge fields from multiple nested arrays in JSON input into new payload array using Dataweave

1 Answer 1

1 Comment

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

1 Comment

Your Answer

Sign up or log in

Post as a guest

Related