Setting a variable in batch using powershell

Question

I have been racking my brain trying to figure this out.

this code

@echo off
powershell $Yesterday = (get-date((get-date).addDays(-1)) -format yyyyMMdd)
echo %Yesterday%

::neither one of these echo anything

@echo off
powershell Set-Variable -Name "Yesterday" -Value (get-date((get-date).addDays(-1)) -format yyyyMMdd)
echo %Yesterday%

should both return a response with yesterdays date (formatted as yyyMMdd), however, they do not. Using powershell, the following code does indeed work and return the correct response:

$Yesterday = (get-date((get-date).addDays(-1)) -format yyyyMMdd)
Write-Host $Yesterday

::Both of these work in powershell

Set-Variable -Name "Yesterday" -Value (get-date((get-date).addDays(-1)) -format yyyyMMdd)
Write-Host $Yesterday

however it does not work when used in batch. Any ideas why? I am trying to set the variable %Yesterday% in order to use it later in the script, but its not behaving itself as I expected. I'm sure its something simple, but I'm not seeing what it is right now.

similar question

Hackoo · Accepted Answer · 2019-12-06 11:14:52Z

6

This what you should use as code to set variable using Powershell and Batch

@echo off & color 0A
Title Setting a variable in batch using powershell
Set psCmd="get-date((get-date).addDays(-1)) -format yyyyMMdd"
Call :RunPS %psCmd% YesterDay
Echo YesterDay was %YesterDay%
pause & Exit
::----------------------------------------------------------------------
:RunPS <PassPSCMD> <Return value to be set as variable>
  for /F "usebackq tokens=*" %%i in (`Powershell %1`) do set "%2=%%i"
Goto:eof
:: End of :RunPS function
::----------------------------------------------------------------------

answered Dec 6, 2019 at 11:14

Hackoo

18.9k3 gold badges48 silver badges84 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

David · Accepted Answer · 2019-12-28 02:31:51Z

0

Here is a one liner that will provide a var for yesterday's date in your batch script. The second line cleans up the temp file used to create the variable.

powershell -command "((Get-date).AddDays(-1)).ToString('yyyyMMdd')">captureVar && set /p Yesterday=<captureVar
if exist captureVar del captureVar

Line 1 starts out by instructing the cmd line to use PowerShell for the commands contained within the double quotes.

powershell -command "the powershell command(s)"

As it's name implies, the first PowerShell cmdlet will perform a function to Get-Date. Then, AddDays is used to change the date from the current value. A negative number will subtract and a positive number will add.

The default format looks like Friday, December 20, 2019 6:18:29 PM

To change the format, you must change the date into a string with format instructions

.ToString('dddd MM/dd/yyyy HH:mm:ss.ffff K')

The output of the PowerShell command is redirected into a file named captureVar. Another option would have been to have PowerShell write it to a file.

powershell -command "((Get-date).AddDays(-1)).ToString('yyyyMMdd') | set-content 'captureVar'" && set /p Today=<captureVar

I used && to make it a one liner. But you can set the var anytime after value has been written to the file.

set /p Today=<captureVar

The next line cleans up the temp file used to help create the var.

edited Dec 28, 2019 at 2:31

answered Dec 28, 2019 at 1:14

David

1841 silver badge7 bronze badges

2 Comments

phuclv Over a year ago

saving output to file is not a good idea for temporary items, and you need to delete it after using

David Over a year ago

@phuclv you are absolutely correct. I've added a line to clean up the temp file used to create the var.

Scepticalist · Accepted Answer · 2019-12-06 09:14:05Z

-3

Defne the variable in batch, retrieve from Powershell

@echo off
%Yesterday% = powershell -command (get-date((get-date).addDays(-1)) -format yyyyMMdd)
echo %Yesterday%
pause

answered Dec 6, 2019 at 9:14

Scepticalist

3,9331 gold badge16 silver badges31 bronze badges

Collectives™ on Stack Overflow

Setting a variable in batch using powershell

3 Answers 3

Comments

2 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

Comments

2 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related