converting assembler function in Delphi which runs on windows to delphi/c++ to execute on Linux

Question

I have this assembler function in my application wriiten in delphi and this executes well on windows .But my requirement is to execute it on Linux as i am migrating my application on Linux. And while compiling this function in Linux i got error : "Unsupported language feature: 'ASM'".

Anybody can help or suggest how to implement it either in c++ or in delphi so that it works for Linux. sharing my code:

type 
  PVersionizedPointer = ^TVersionizedPointer; 
  TVersionizedPointer = packed record 
    Ver : NativeInt; 
    Ptr : Pointer; 
  end; 
  TVersionizedPointerStorage = array[0 .. 2 * sizeof(TVersionizedPointer) - 1] of byte; 

function GetVersionizedPointer(var PointerStorage : TVersionizedPointerStorage) : 
    PVersionizedPointer; assembler;
const
  vp_size = sizeof(TVersionizedPointer);  
      // Note: sizeof(any) inside asm is always $31
  asm
    {$ifdef CPUX86}
      add EAX, vp_size - 1
      and EAX, not(vp_size - 1)
    {$endif}
    {$ifdef CPUX64}
      mov RAX, RCX
      add RAX, vp_size - 1
      and RAX, not(vp_size - 1)
    {$endif}
  end;
end;

Could you give the definition of TVersionizedPointerStorage? — Olivier
– Olivier, Commented Apr 21, 2020 at 9:59
Some hint of what the code is supposed to do would be helpful to. The answer is probably not to bother with assembly code and trust the compiler to generate good code — Alan Birtles
– Alan Birtles, Commented Apr 21, 2020 at 10:09
Please don't add details in comments. You can edit the question and add the information there — David Heffernan
– David Heffernan, Commented Apr 21, 2020 at 11:53

Andreas Rejbrand · Accepted Answer · 2020-04-21 12:31:07Z

5

It's probably easiest just to concentrate on what the x86 version does:

function GetVersionizedPointer(var PointerStorage: TVersionizedPointerStorage): PVersionizedPointer;
const
  vp_size = sizeof(TVersionizedPointer);
asm
  add EAX, vp_size - 1
  and EAX, not(vp_size - 1)
end;

The x86 ABI means that the address of PointerStorage is passed into the function in EAX. The return value, another address, is also retuned in EAX. That knowledge lets us understand what the function does, and allows us to write it like this in Pascal:

function GetVersionizedPointer(var PointerStorage: TVersionizedPointerStorage): PVersionizedPointer;
var
  Address: NativeUInt;
begin
  Address := NativeUInt(@PointerStorage);
  Address := Address + (SizeOf(TVersionizedPointer) - 1);
  Address := Address and not (SizeOf(TVersionizedPointer) - 1);
  Result := PVersionizedPointer(Address);
end;

I've written it out rather verbosely to make it clear what each step is doing. The address variable is assigned the address of PointerStorage, and so serves the same role as EAX in the original version.

Make your life easier in the future by using this pure Pascal version, and losing the assembler code.

edited Apr 21, 2020 at 12:31

Andreas Rejbrand

110k8 gold badges298 silver badges404 bronze badges

answered Apr 21, 2020 at 10:30

David Heffernan

616k46 gold badges1.1k silver badges1.5k bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Arnaud Bouchez Over a year ago

Remark: This kind of functions may benefit of being inlined. And inlining such pascal code is very likely to be faster than calling an external asm stub. :)

Arnaud Bouchez · Accepted Answer · 2020-04-22 07:51:35Z

3

This function aim is to align the storage in memory. It is perfectly pointless in modern Intel/AMD CPUs. It may have had a benefit on a 8086 CPU, but not any more. Sounds definitively like wrong/premature optimization.

This whole alignment subroutine may just be avoided: it would make code cleaner and also faster. Just get rid of TVersionizedPointerStorage and only use TVersionizedPointer.

Not aligning the data will be faster, since you won't need to compute any alignment any more, and you would just use the needed memory, whereas TVersionizedPointerStorage is always using twice the size, so it pollutes the CPU L1 cache for no benefit, and add unneeded memory allocation.

edited Apr 22, 2020 at 7:51

answered Apr 21, 2020 at 11:20

Arnaud Bouchez

43.1k3 gold badges78 silver badges165 bronze badges

2 Comments

Anna Over a year ago

Hi @Arnaud Actually this is very old code from 90's and written by other guys , so recently this application/tool came to us and we are struggling to make it work on lInux and understand it completely.

Arnaud Bouchez Over a year ago

Then clean it from deprecated tricks like TVersionizedPointerStorage. It will help understand it for sure.

Collectives™ on Stack Overflow

converting assembler function in Delphi which runs on windows to delphi/c++ to execute on Linux

2 Answers 2

1 Comment

2 Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

2 Comments

Your Answer

Sign up or log in

Post as a guest

Related