How to convert string into an array in clojure

Question

I want to convert the string into an array, I have tried some steps but not getting the desired result.

(:require [clojure.string :as str])

(def stringval "fruit==Mango,fruit==Papaya;veggie==Onion,veggie==Potato")

(defn formatting [strFilters]   
(let [filters (str/split strFilters #";")]
    (for [filter filters]
      (let [eachFilter (str/split filter #",")]
        (for [each eachFilter]
          (let [items (str/split each #"==")]
            items
            )))))) 
(formatting stringval)

I am getting below output

((["fruit" "Mango"] ["fruit" "Papaya"]) (["veggie" "Onion"] ["veggie" "Potato"]))

I want clojure function which returns the below array

Array
(
    [fruit] => Array
        (
            [0] => Mango
            [1] => Papaya
        )

    [veggie] => Array
        (
            [0] => Onion
            [1] => Potato
        )

)

Do you mean Java array? So the result should have the same structure as the result of (to-array-2d [["Mango" "Papaya"] ["Onion" "Potato"]])? — Martin Půda
– Martin Půda, Commented Jan 12, 2023 at 11:29

cfrick · Accepted Answer · 2023-01-12 13:25:30Z

3

You want a list of maps, so you have to turn your current intermediate results into a map. You can do this with group-by and some some post-processing, or you can use merge-with conj if you shape the result from the innermost for in preparation for it. Also note, that for can have :let in it.

(require '[clojure.string :as str])

(def s "fruit==Mango,fruit==Papaya;veggie==Onion,veggie==Potato")

(for [g (str/split s #";")]
  (apply merge-with into
         (for [kv (str/split g #",")
               :let [[k v] (str/split kv #"==")]]
           {k [v]})))
; → ({"fruit" ["Mango" "Papaya"]} {"veggie" ["Onion" "Potato"]})

And in case your target-output there is from PHP or some other language, that got their basic data structures wrong, and you actually just want a map with the keys to arrays of values, you just have to to shift the merge-with into out and you can also split for ; and , one swoop.

(apply merge-with into
       (for [kv (str/split s #"[;,]")
             :let [[k v] (str/split kv #"==")]]
         {k [v]}))
; → {"fruit" ["Mango" "Papaya"], "veggie" ["Onion" "Potato"]}

edited Jan 12, 2023 at 13:25

answered Jan 12, 2023 at 13:02

cfrick

37.3k7 gold badges61 silver badges76 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

cfrick Over a year ago

Note, that just using split will ignore problems when ;, ,, and == must be allowed for keys and values and some sort of quoting is used. Using a proper parser would be the defensive choice.

leetwinski · Accepted Answer · 2023-01-12 17:20:48Z

2

one more option is to get all the pairs with re-seq and reduce it with grouping:

(->> stringval
     (re-seq #"([^,;].+?)==([^,;$]+)")     
     (reduce (fn [acc [_ k v]] (update acc k conj v)) {}))

;;=> {"fruit" ("Papaya" "Mango"), "veggie" ("Potato" "Onion")}

answered Jan 12, 2023 at 17:20

leetwinski

17.9k2 gold badges21 silver badges44 bronze badges

Collectives™ on Stack Overflow

How to convert string into an array in clojure

2 Answers 2

1 Comment

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

1 Comment

Comments

Your Answer

Sign up or log in

Post as a guest

Related