Perl, comparing scalar to array (with regex?)

Question

I'll be brief so I don't waste your time;

Simple problem, i have an array of say, hundreds of dogs

my @dogs = qw(Shepard Lab Dalmation Husky Chow Pitbull ...)

and i want to compare it to a single dog

my $doggy = "Shepard";

pretty stupid i know, but how would i do that?

# Regex match against array?
# (This doesnt even work but its how i would think of doing it)
if ($doggy =~ /@dogs/) {
print $doggy;
}

Thanks for any answers in advance, I appreciate you guys helping me with what is probably a really stupid question. Thank you

So, you want to "compare it to a single dog" - wouldn't that comparison always return false, as they're unequal? Or do you want to find the index of your dog in the list of dogs? Do you want to verify that your dog is listed? Please be a little more specific. — Nightfirecat
– Nightfirecat, Commented Nov 21, 2011 at 18:47
Yes, like you said, find my index of the dog, in the lists, so i can see if the shepard is in the master dog list or not — user1058357
– user1058357, Commented Nov 21, 2011 at 18:48
stackoverflow.com/questions/720482/… stackoverflow.com/q/1915746 stackoverflow.com/q/2383505 stackoverflow.com/q/2678503 stackoverflow.com/q/2925604 stackoverflow.com/q/3086874 stackoverflow.com/q/3222138 — daxim
– daxim, Commented Nov 21, 2011 at 19:57

FailedDev · Accepted Answer · 2011-11-21 18:49:10Z

5

I would do it like this :

my %hDogs = map { $_ => 1 } @dogs;

if(exists($hDogs{$doggy})) { ... }

answered Nov 21, 2011 at 18:49

FailedDev

27k9 gold badges56 silver badges74 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

user1058357 Over a year ago

Okay so convert the 'master dog list' to a Hash, and use that if-exists statement to see if its in the hash, thanks for the answer I was wondering if i should use hash's or not

FailedDev Over a year ago

@user1058357 There is more than 10 ways to do this :)

user1058357 Over a year ago

Hehe, must be pretty bad if i can only think of 1 that doesnt work :P

FailedDev Over a year ago

@user1058357 We have all been through that. Don't let it get to you.

flesk · Accepted Answer · 2011-11-21 19:24:09Z

4

You can just use grep:

my @dogs = qw(Shepard Lab Dalmation Husky Chow Pitbull);
my @wanted_dogs = grep {/^Shepard$/} @dogs;
print "@wanted_dogs\n";

Result:

Shepard

The regex can be changed as wanted, and if you're only interested in the first matching dog, you'll find that in $wanted_dogs[0].

edited Nov 21, 2011 at 19:24

answered Nov 21, 2011 at 18:49

flesk

7,5994 gold badges27 silver badges34 bronze badges

2 Comments

user1058357 Over a year ago

Thank you, this answer is helpful as well

flesk Over a year ago

My pleasure. It's what grep was made for, and it does it well.

toolic · Accepted Answer · 2011-11-21 18:59:57Z

3

Smart match operator:

use warnings;
use strict;

my @dogs = qw(Shepard Lab Dalmation Husky Chow Pitbull);
my $doggy = "Shepard";
if ($doggy ~~ @dogs) {
    print $doggy;
}

answered Nov 21, 2011 at 18:59

toolic

62.9k21 gold badges81 silver badges130 bronze badges

Comments

Quentin · Accepted Answer · 2011-11-21 18:59:44Z

2

Assuming you don't really want a regular expression match and just want to see if there is an exact match somewhere in the list, then you have a number of options.

Smart match is the relatively new, but simplest and possibly fastest approach.

The classic methods are grep and List::Util::first. You can adjust the latter two to use a regex instead of eq if you do want to (for example) match "Shepard" when $dog is "Shep".

use strict;
use warnings;
use v5.10;

my @dogs = qw(Shepard Lab Dalmation Husky Chow Pitbull);
my $dog = "Shepard";
my $cat = "Ocicat";

say "Smart match";
say $dog ~~ @dogs;
say $cat ~~ @dogs;

say "Grep";
say grep { $_ eq $dog } @dogs;
say grep { $_ eq $cat } @dogs;

say "List::Util";
use List::Util qw/first/;
say first { $_ eq $dog } @dogs;
say first { $_ eq $cat } @dogs;

answered Nov 21, 2011 at 18:59

Quentin

949k136 gold badges1.3k silver badges1.4k bronze badges

2 Comments

user1058357 Over a year ago

Thanks for the input, any advice is appreciated not sure what method ill be using at this point

Quentin Over a year ago

Use smart match unless you have an out of date Perl that you can't upgrade (in which case use List::Util).

Eric Strom · Accepted Answer · 2011-11-21 18:48:11Z

1

There are techniques using the newer smart-match operator, but I prefer the old classic:

my $dogs_re = join '|' => map quotemeta, @dogs;

if ($doggy =~ /$dogs_re/) {...}

That creates a regex alternation of your dog types, after quoting any regex special characters in the names.

You could compile the regex as well if you want:

$_ = qr/$_/ for $dogs_re;

which would be placed after the line defining $dogs_re, and may offer some performance benefits if you will be using the regex many times.

answered Nov 21, 2011 at 18:48

Eric Strom

40.2k2 gold badges83 silver badges152 bronze badges

5 Comments

user1058357 Over a year ago

This is a little hard to wrap my mind around, but im sure its a great solution, ill read it a few hundred more times :P, thank you for the response

user1058357 Over a year ago

Ahh ok i understand, itd be the equivalent of a regex with multiple match options : (Shepard|Husky|Chow), and then it could execute a regex statement, this is really useful as i will be re-using the regex hundreds of times and need to have it compiled for speed, Thanks much.

Zaid Over a year ago

@user1058357 : Think about using a module that optimizes such regexes. Regexp::Assemble comes to mind

Eric Strom Over a year ago

@Zaid => Starting with 5.9.2, Perl's regex engine will automatically optimize chained alternations like this into a trie.

Eugene Yarmash Over a year ago

$dogs_re = qr/$dogs_re/ is shorter and more comprehensible, imho.

TLP · Accepted Answer · 2011-11-21 19:15:53Z

0

I would probably choose the hash lookup solution for best answer, but there are many ways to do this. This is one of them.

Note that this uses our dog name as the regex and iterates it over the list instead of the other way around.

use v5.10; # needed for say
@dogs=qw(Shepherd Lab Poodle Foo Bar); 
$dog = 'Lab'; 
/\Q$dog\E/i and say for @dogs;"

You can control how strict the match is:

/\Q$dog\E/i is least strict, ignore case, match anywhere in word. E.g. "lab" will match "Yellow Lab", "Labrador" etc.

/^\Q$dog\E$/ is most strict, match case, match entire word.

answered Nov 21, 2011 at 19:15

TLP

68.2k10 gold badges97 silver badges156 bronze badges

Comments

Andro Selva · Accepted Answer · 2012-10-29 06:36:37Z

0

Try this,

$" = "|";
my @dogs=qw(Shepherd Lab Poodle Foo Bar);
my $temp = "@dogs";
my $dog = "Lab";
print "$1 found" if ($dog =~ /($temp)/);

edited Oct 29, 2012 at 6:36

Andro Selva

54.4k53 gold badges195 silver badges244 bronze badges

answered Feb 24, 2012 at 7:14

Mohammed Rizwan

1

Collectives™ on Stack Overflow

Perl, comparing scalar to array (with regex?)

7 Answers 7

4 Comments

2 Comments

Comments

2 Comments

5 Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

7 Answers 7

4 Comments

2 Comments

Comments

2 Comments

5 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related