Classes within Coffeescript 'Namespace'

Question

I found this snippet on the Coffeescript FAQ for creating simplistic namespaces ..

# Code:
#
namespace = (target, name, block) ->
  [target, name, block] = [(if typeof exports isnt 'undefined' then exports else window), arguments...] if arguments.length < 3
  top    = target
  target = target[item] or= {} for item in name.split '.'
  block target, top

# Usage:
#
namespace 'Hello.World', (exports) ->
  # `exports` is where you attach namespace members
  exports.hi = -> console.log 'Hi World!'

namespace 'Say.Hello', (exports, top) ->
  # `top` is a reference to the main namespace
  exports.fn = -> top.Hello.World.hi()

Say.Hello.fn()  # prints 'Hi World!'

That is all well and good, but I am having a great deal of trouble doing this with the class keyword. Such that ..

namespace 'Project.Something', (exports) ->
   exports.something = -> class something
    // .. code here
   exports.somethingElse = class somethingElse extends something

can anyone shed some light on the syntax that would accomplish this?

Chris Subagio · Accepted Answer · 2012-01-14 19:25:48Z

24

Even better, the class syntax allows for the name to actually be in the form of a member, so you can actually just do:

namespace 'Secrets', (exports) ->
  class exports.Hello
    constructor: ->
      @message = "Secret Hello!"

a = new Secrets.Hello
console.log a.message

Full fiddle here: http://jsfiddle.net/7Efgd/1/

answered Jan 14, 2012 at 19:25

Chris Subagio

6,3491 gold badge17 silver badges7 bronze badges

Sign up to request clarification or add additional context in comments.

1 Comment

Sandro Over a year ago

This is a valid solution as well. It's really a matter of preference. I find the example above a little easier for me to understand.

user229044 · Accepted Answer · 2013-02-25 15:09:54Z

19

The trick is to create the class first

class MyFirstClass
  myFunc: () ->
    console.log 'works'

class MySecondClass
  constructor: (@options = {}) ->
  myFunc: () ->
    console.log 'works too'
    console.log @options

Then somewhere near the end of the file export all the classes than need to be exposed.

namespace "Project.Something", (exports) ->
  exports.MyFirstClass = MyFirstClass
  exports.MySecondClass = MySecondClass

Later on you can use the classes as so:

var firstClass = new Project.Something.MyFirstClass()
firstClass.myFunc()

var secondClass = new Project.Something.MySecondClass 
  someVar: 'Hello World!'

secondClass.myFunc()

edited Feb 25, 2013 at 15:09

user229044♦

241k41 gold badges347 silver badges350 bronze badges

answered Jan 4, 2012 at 17:20

Sandro

4,7711 gold badge36 silver badges41 bronze badges

4 Comments

Ciel Over a year ago

There we go! It was so simple, but so frustrating at the same time. Thank you!

jackyalcine Over a year ago

There should be a method that does this for you :(

Abe Petrillo Over a year ago

Doesn't this defeat the purpose of Namespacing? Seen as MyFirstClass is now defined both in the Namespace and outside of it? @ChrisSubagio's answer seems like a more correct way to do it.

Sandro Over a year ago

No. Coffeescript wraps that file within an anonymous function so MyFirstClass is not leaked to the global namespace. It's only exposed to the global namesapce through the namespace function.

Sundar · Accepted Answer · 2013-02-14 07:43:55Z

1

How about using something like this?

module =
    Hello: class Hello extends Backbone.Model
        constructor: ->
            @message = 'Hello'

    Hello2: class Hello2 extends Backbone.View
        constructor: ->
            @message = 'Hello2'

answered Feb 14, 2013 at 7:43

Sundar

1831 silver badge6 bronze badges

Collectives™ on Stack Overflow

Classes within Coffeescript 'Namespace'

3 Answers 3

1 Comment

4 Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

1 Comment

4 Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related