How to create multiple multi-dimensional arrays from STDIN in perl?

Question

So I'm getting input from STDIN like:

Blank lines separate the matrices, so the above input should create two multi-dimensional arrays...I know how to create one (code below), but how do I create multiple ones depending on how many blank lines the user inputs?

I won't know how many arrays the user wants to create so how can I dynamically create arrays depending on the blank lines in the user input?

my @arrayrefs;


while(<>)
{

chomp;

    my @data = split(/\s+/,$_);
    push @arrayrefs, \@data;
}


for $ref (@arrayrefs){
    print "[@$ref] \n";
}

TLP · Accepted Answer · 2012-02-27 12:49:10Z

1

With your data, I'd say using paragraph mode for the input stream would be a good idea. That is basically setting the input record separator $/ to "\n\n", but in this case we will use "", which is a bit more magical in that it is flexible with extra blank lines.

use strict;
use warnings;
use Data::Dumper;

sub parse_data {
    my @matrix = map { [ split / / ] } split /\n/, shift;
    return \@matrix;
}

my @array;
$/ = "";
while (<>) {
    push @array, parse_data($_);
}
print Dumper \@array;

The map/split statement is not as complex as it looks. Reading from right to left:

shift an argument from the argument list @_
split that argument on newline
take each those (i.e. map them) split arguments and split them again on space, and put the result inside an anonymous array, using brackets [ ].

All done.

answered Feb 27, 2012 at 12:49

TLP

68.2k10 gold badges97 silver badges156 bronze badges

Sign up to request clarification or add additional context in comments.

7 Comments

Zaid Over a year ago

Alternatively: my @array = map { parse_data( $_ ) } <>;

flesk Over a year ago

+1. You could change the body of parse_data to just [map { [ split / / ] } split /\n/, shift] without losing readability as well.

TLP Over a year ago

@flesk I could, but this way, I leave the name of the variable as a hint as to what is returned. Also, I feel that an explicit return statement is easier to understand.

Zaid Over a year ago

@flesk : "without losing readability"? There's an awful lot going on in that one line and should be subbified IMO

flesk Over a year ago

@Zaid: I agree about that, but in my opinion this solution is already half-golfed, and requires some mental acrobatics to grasp without the provided explanation anyway. But then again, with the change I suggested, why not place it directly into the map you suggested I guess. It's a slippery slope.

|

Jonathan Leffler · Accepted Answer · 2012-02-27 08:14:08Z

It won't win any Code Golf competition, but it does seem to work:

$ cat data
1 2 3
4 5 6
7 6 3

4 3 2
2 3 5
2 5 1
$ cat xx.pl
#!/usr/bin/env perl
use strict;
use warnings;

my @matrices;
my @matrix;

sub print_matrices()
{
    print "Matrix dump\n";
    foreach my $mref (@matrices)
    {
        foreach my $rref (@{$mref})
        {
            foreach my $num (@{$rref})
            {
                print " $num";
            }
            print "\n";
        }
        print "\n";
    }
}

while(<>)
{
    chomp;
    if ($_ eq "")
    {
        my(@result) = @matrix;
        push @matrices, \@result;
        @matrix = ();
    }
    else
    {
        my @row = split(/\s+/,$_);
        push @matrix, \@row;
    }
}

# In case the last line of the file is not a blank line
if (scalar(@matrix) != 0)
{
        my(@result) = @matrix;
        push @matrices, \@result;
        @matrix = ();
}

print_matrices();
$ perl xx.pl data
Matrix dump
 1 2 3
 4 5 6
 7 6 3

 4 3 2
 2 3 5
 2 5 1

$

flesk · Accepted Answer · 2012-02-27 08:48:07Z

0

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my @arrays = [];

while (<>) {
    if (my @array = /(\d+)/g) {
        push $arrays[$#arrays], \@array; 
    } else {
        push @arrays, [];   
    }
}

$Data::Dumper::Indent = 0;
printf("%s\n", Dumper $arrays[0]);
printf("%s\n", Dumper $arrays[1]);

Output:

$VAR1 = [['1','2','3'],['4','5','6'],['7','6','3']];
$VAR1 = [['4','3','2'],['2','3','5'],['2','5','1']];

answered Feb 27, 2012 at 8:48

flesk

7,5994 gold badges27 silver badges34 bronze badges

Collectives™ on Stack Overflow

How to create multiple multi-dimensional arrays from STDIN in perl?

3 Answers 3

7 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

7 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related