Batch Script - Create Dynamic Variable Names or Array in For Loop

Question

I would like to ask you if you can advise.

I don't know if it is possible to create dynamic variable names in batch or array or something like this. For example set c=0 before for loop and then set c = c+1 inside for loop and use this number to create dynamic variable name inside for loop e.g.: set entry%c% = 'somestring'

and afterwards use these numbered variables to print output outside for loop e.g.: echo %entry1% echo %entry2%

Example:

@echo off

set /a c=1

for %%i in (list.txt) do (

set /a c=c+1
set entry%c% = %%i

)

echo %entry1%
echo %entry2%

Thanks for help.

Look into delayed expansion variables. setLocal enableDelayedExpansion. — unclemeat
– unclemeat, Commented Jun 15, 2014 at 23:44

Magoo · Accepted Answer · 2014-06-16 01:02:27Z

4

I'd use

for /f "tokens=1*delims=[]" %%a in ('find /n /v "" list.txt') do set "entry%%a=%%b"

but a word of warning about

set entry%c% = %%i

Batch is sensitive to spaces in a SET statement. Had this worked, it would set a variable named "entry1Space" to a value of "Spacethefirstlineofthefile".

The set "var=value" syntax I've used ensures that any trailing spaces on the batch line are not included in the value assigned to var.

answered Jun 16, 2014 at 1:02

Magoo

80.8k8 gold badges68 silver badges92 bronze badges

Sign up to request clarification or add additional context in comments.

2 Comments

unclemeat Over a year ago

+1 This is quite clever. I like the use of find's /v switch to remove the possibility of empty variables, and of course /n to number the variables. A very good one liner.

damian1baran Over a year ago

Great! Thanks - exactly what I've been looking for. I appreciate your help.

unclemeat · Accepted Answer · 2015-02-11 21:27:30Z

3

You need to use delayed expansion variables, otherwise c will always expand to the same value.

You also need to remove the spaces in your set statement. set entry%c% = %%i will create a variable called (for example) entry1<space>, which you would have to expand like so - %entry1 %. So just remove those spaces around the = operator.

@echo off

setLocal enableDelayedExpansion
set c=0

for %%i in (list.txt) do (
    set /a c+=1
    set entry!c!=%%i
)

echo %entry1%
echo %entry2%

Also if you wanted to loop through all the variables you created, you could do something like the following.

for /L %%i in (!c!, -1, 1) do echo !entry%%i!

or

for /L %%i in (1, 1, !c!) do echo !entry%%i!

edited Feb 11, 2015 at 21:27

answered Jun 15, 2014 at 23:49

unclemeat

5,2075 gold badges32 silver badges55 bronze badges

Comments

Philip Mn · Accepted Answer · 2024-07-23 00:28:26Z

0

Here is a snippet I used to list adb devices connected. It assigns each device to a dynamic variable called "device[n]" where n is the index and 1 is the index of the first device in the list.

setlocal enabledelayedexpansion
set i=0
set sum_of_devices=0

REM get list of connected devices
for /f "eol=L tokens=1" %%a in ('adb devices ^| findstr "device"') do (
    set /a i=i+1

    REM device is assigned to dynamic variable 
    for /f "tokens=1" %%b in ('echo device_!i!') do (
        set %%b=%%a
    )
)
echo !device_1!
echo !device_2!
endlocal

answered Jul 23, 2024 at 0:28

Philip Mn

1

Collectives™ on Stack Overflow

Batch Script - Create Dynamic Variable Names or Array in For Loop

3 Answers 3

2 Comments

Comments

Comments

Your Answer

Linked

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

2 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Linked

Related