Webpage values wont update

Question

I've been trying to run the following esp32 LED PWM code to change the LED's brightness, and show the current PWM duty on the webpage, but the PWM values on the webpage won't change until I hit the submit button twice.

#include <Arduino.h>
#include <WiFi.h>
#include <WebServer.h>
WebServer ser(80);
int s=0;
String k;



String iso()
{
  k="<p style=\"text-align: center;\"><strong><font size=\"9\">LED PWM</font></strong><font size=\"3\"></font><FORM action=\"/\" method=\"post\"><input type=\"text\" name=\"duty\"><br> <input type=\"submit\" value=\"Submit\">Cureent Duty=";
  k=k+s;
  k=k+"</p>";

  return k;
}

void root()
{
  iso();
  ser.send(200, "text/html", iso());

  if (ser.hasArg("duty")) 
  {
      iso();
      s=ser.arg("duty").toInt();  
      ledcWrite(4, s);
      iso();
      ser.send(200, "text/html", iso());
  }
}





void setup() {
  Serial.begin(9600);
  ledcAttachPin(33, 4);
  ledcSetup(4, 5000, 8);
  WiFi.begin("ssid", "pass");
  Serial.print("\nConnecting To WiFi");
  while (WiFi.status()!=WL_CONNECTED)
  {

    Serial.printf("\n.");
  }
  Serial.print("\nConnected");

  ser.on("/", root);
  ser.begin(80);
}



void loop() {
  ser.handleClient();
}

Here's a GIF addressing the issue

upvote for visually demonstrating the issue

jsotola
– jsotola

2019-06-11 16:11:51 +00:00
Commented Jun 11, 2019 at 16:11 — jsotola
– jsotola, Commented Jun 11, 2019 at 16:11

Edgar Bonet · Accepted Answer · 2019-06-11 08:12:29Z

When the client sends you a request, you should answer only once. Your root() function attempts to answer twice whenever the request contains the argument “duty”. The client will not handle a duplicate response to a single request.

Here is your root() function:

void root()
{
  iso();
  ser.send(200, "text/html", iso());  // ← first response

  if (ser.hasArg("duty"))
  {
      iso();
      s=ser.arg("duty").toInt();
      ledcWrite(4, s);
      iso();
      ser.send(200, "text/html", iso());  // ← second response
  }
}

You may notice that the first response was sent before updating the duty cycle.

The proper way to handle the request is to first handle the request parameters, if any, then send the response:

void root()
{
  if (ser.hasArg("duty")) {
    s = ser.arg("duty").toInt();
    ledcWrite(4, s);
  }
  ser.send(200, "text/html", iso());  // ← only sent once
}

As a side note, there is absolutely no need to build the response five times (you have five calls to iso() within root()) when you only need it once!

Stack Exchange Network

Webpage values wont update

1 Answer 1

Your Answer

Hot Network Questions

Webpage values wont update

1 Answer 1

Your Answer

Sign up or log in

Post as a guest

Related

Hot Network Questions