IsTimeSet library - Assign variables

Question

i get the current time with the example code istimneforset, everything works fine.

now i want to get the current time from the function "Serial.println(timeClient.getFormattedTime());" and i am trying to cache the first character of the array.

code:

#include <NTPClient.h>
// Change the next line to use with a different map/shield
#include <ESP8266WiFi.h>
//#include <WiFi.h> // for WiFi shield
//#include <WiFi101.h> // for WiFi 101 shield or MKR1000
#include <WiFiUdp.h>

const char *ssid =" *";
const char *password = "*";

WiFiUDP ntpUDP;
// initialized to a time offset of 10 hours
NTPClient timeClient(ntpUDP, "pool.ntp.org", 36000, 60000);
// HH:MM:SS
// timeClient is initialized to 10:00:00 if it does not receive an NTP packet
// before the timeout of 100ms is received.
// Without isTimeSet(), the LED would be lit even though the time was
// was not yet set correctly.


const int hour = 10;
const int minute = 0;

void setup(){
  Serial.begin(9600);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay (500);
    Serial.print(".");
  }

  timeClient.begin();
}

void loop() {
  timeClient.update();

 //Serial.println(timeClient.getFormattedTime());

 int stund2  = (timeClient.getFormattedTime()[0]);

Serial.println(stund2);

}

unfortunately it always gives me a wrong value. my goal is to have the current hour in a variable. can someone help me? thanks!

Serial.println(timeClient.getFormattedTime()); -> 01:41:58 Serial.println (stund2); -> 48 — Mike
– Mike, Commented Dec 4, 2022 at 15:43

st2000 · Accepted Answer · 2022-12-04 16:13:28Z

There are a number of post in threads here and here that suggest using the NTPClient here.

Also, if we inspect that GIT repository's copy of NTPClient.cpp starting a line 155 we see the function for getFormattedTime():

String NTPClient::getFormattedTime(unsigned long secs) {
  unsigned long rawTime = secs ? secs : this->getEpochTime();
  unsigned long hours = (rawTime % 86400L) / 3600;
  String hoursStr = hours < 10 ? "0" + String(hours) : String(hours);

  unsigned long minutes = (rawTime % 3600) / 60;
  String minuteStr = minutes < 10 ? "0" + String(minutes) : String(minutes);

  unsigned long seconds = rawTime % 60;
  String secondStr = seconds < 10 ? "0" + String(seconds) : String(seconds);

  return hoursStr + ":" + minuteStr + ":" + secondStr;
}

...we see that this function returns a String resembling "hh:mm:ss" where hh is hours, mm is minutes and ss is seconds.

To extract only hours we would have to "cut" the string or parse the string using the ":" character, use only the "hh" portion of the string and convert that back into a number.

This is complex. Instead, consider using the function getHours():

int NTPClient::getHours() {
  return ((this->getEpochTime()  % 86400L) / 3600);
}

... this uses the epoch time after taking off the date (modulo 86400) and taking off the minutes and seconds (divide by 3600) leaving only the hours.

chrisl · Accepted Answer · 2022-12-05 08:47:28Z

While st2000 gave a good answer about how to do it instead, I wanted to explain what actually went wrong with your first solution.

You are seeing the difference between binary and ASCII encoded data. Using timeClient.getFormattedTime() will give you an ASCII encoded string. Such a string is an array of chars, each one representing one character (according to the ASCII table) until the string gets terminated with the null character \0.

You are taking the first character and assign it to an integer variable. The value will be directly copied into that variable. But the first element in that char array is the ASCII digit 0, which is the equivalent of decimal 48. And that is what you get from your code. Also the hour field of that string is 2 characters wide, so you need to read both of them, not just the first character.

If you want to extract numbers from a string, you cannot just assign them. You need to parse the data correctly. For that you would tokenize the string (split it in individual parts with data) (for example with strtok()) and then parse each token with a corresponding function. To parse an integer value from a string you can use atoi(). This function will read the string, until a non-digit character appears, and convert that to an integer.

So - since we are only interested into the first number/token in that string, you can leave out the tokenizing and just parse that string (since after the number of hours there is always the : character, which is a non-digit character):

int stund2 = atoi(timeClient.getFormattedTime());

I have not tested this, but it should also work, though not that efficient as the solution of st2000, since parsing string data is commonly more complex than working directly with integer numbers.

Stack Exchange Network

IsTimeSet library - Assign variables

2 Answers 2

Your Answer

Hot Network Questions

IsTimeSet library - Assign variables

2 Answers 2

Your Answer

Sign up or log in

Post as a guest

Related

Hot Network Questions